예를 들어 다음 Excel 파일이 있습니다.
| USER ID | SCORE | TOTAL SCORE | TOTAL BONUS | NOTE |
| ------- | ----- | ----------- | ----------- | ----- |
| 18 | 10 | | | |
| 18 | 25 | | | |
| 18 | 15 | | | |
| 18 | 5 | | | bonus |
| 18 | 30 | | | |
| 24 | 2 | | | |
| 24 | 7 | | | |
| 24 | 21 | | | |
| 32 | 6 | | | |
| 32 | 9 | | | bonus |
| 32 | 18 | | | |
| 32 | 40 | | | |
각 USER ID의 첫 번째 행에는 보너스(참고 열로 식별 가능)를 제외한 총 점수 합계와 별도로 보너스 합계(있는 경우 그렇지 않으면 0이 됨)가 있어야 합니다.
예제의 결과는 다음과 같아야 합니다.
| USER ID | SCORE | TOTAL SCORE | TOTAL BONUS | NOTE |
| ------- | ----- | ----------- | ----------- | ----- |
| 18 | 10 | 80 | 5 | |
| 18 | 25 | | | |
| 18 | 15 | | | |
| 18 | 5 | | | bonus |
| 18 | 30 | | | |
| 24 | 2 | 30 | 0 | |
| 24 | 7 | | | |
| 24 | 21 | | | |
| 32 | 6 | 64 | 9 | |
| 32 | 9 | | | bonus |
| 32 | 18 | | | |
| 32 | 40 | | | |
함수를 사용하여 합계를 자동화하는 것이 가능합니까? 아마 SUMIF()?
답변1
테이블 시작 날짜:A1
Total Score: C2: =IF(A2=A1,"",SUMIF($A$2:$A$13,A2,$B$2:$B$13) -SUMIFS($B$2:$B$13,$A$2:$A$13,A2,$E$2:$E$13,"bonus"))
Total Bonus: D2: =IF(A2=A1,"",SUMIFS($B$2:$B$13,$A$2:$A$13,A2,$E$2:$E$13,"bonus"))
그리고 채우세요.
답변2
의 도움을 받아이 기사:
몇 가지 추가 열을 만들어야 합니다. 먼저 학생증 총점(보너스 포함)을 계산한 후 총 보너스를 계산하고 마지막으로 총점에서 총 보너스를 빼서 원하는 결과를 얻었습니다.
- 우리는 함수를 사용하여 총점과 총 보너스를 계산합니다
SUMPRODUCT.SUMPRODUCT((A2:A13=A2)*B2:B13)첫 번째 행렬은 사용자 ID이며, 이에 따라 결과가 그룹화되고 합산됩니다. 두 번째 매트릭스는 사용자 점수입니다. - IF 함수를 사용하여 총 보너스를 계산하는 행을 만듭니다.
IF(F2="bonus",B2,0) - 첫 번째 함수와 매우 유사하게 총 보너스를 계산합니다.
SUMPRODUCT((A2:A13=A2)*D2:D13) - 총점에서 총 보너스를 뺍니다.
C2-E2
그 후에 남은 것은 테이블을 수동으로 정리하는 것뿐입니다.
값이 0인 경우 비어 있도록 셀의 서식을 지정하는 옵션도 있습니다("보너스" 열에 적용할 수 있음).
답변3
다음 공식을 시도해 보세요.
총 점수열:
=IF(A2=A1,"",SUMPRODUCT(($A$2:$A$13=A2)*$B$2:$B$13))
총 보너스열:
=IF(A2=A1,"",SUMPRODUCT(N($A$2:$A$13=A2)))
답변4
작동 방식:
D2 셀의 수식:
=IF(A2=A1,"",SUMPRODUCT(($A$2:$A$13=A2)*($E$2:$E$13="bonus"),$B$2:$B$13))C2 셀의 수식:
=IFERROR(IF(A2=A1,"",SUMIF(A$2:A$13,A2,B$2:B$13))-D2,"")
필요에 따라 수식에서 셀 참조를 조정할 수 있습니다.