확대/축소 모드에서 키를 사용한 Microsoft 사진 탐색의 자동 핫키 방향

Question

Microsoft Photos에서는 사진을 확대한 경우 사진 탐색을 허용하지 않으며 기본 확대/축소 수준인 경우에만 가능합니다. 이것은 약간 혼란스럽기 때문에 이 문제를 원활하게 해결하기 위해 Autotkey 방향을 만들기로 결정했습니다.

스크롤 휠은 이유가 무엇이든 항상 Microsoft Photos의 항목을 탐색하므로 내 논리는 탐색(화살표) 키를 누를 때 항상 마우스휠 스크롤을 트리거하는 것이었습니다. 이론적으로는 이것은 훌륭하게 작동하지만 실제로는 작동하지 않습니다.

이유를 아는 사람 있나요? 오토핫키 방향이 잘못된 건가요, 아니면 다른 건가요?

#IfWinActive, ahk_exe Microsoft.Photos.exe
Left::Send {WheelUp}
Right::Send {WheelDown}
#If

Answer 1

이 시도:

#If (WinGetActiveProcessName() = "Microsoft.Photos.exe")

    Left::Send {WheelUp}
    Right::Send {WheelDown}

#If


WinGetActiveProcessName(){ 
; https://www.autohotkey.com/boards/viewtopic.php?t=13818&p=70912#p73137 
    WinGet name, ProcessName, A
    if (name = "ApplicationFrameHost.exe")
    {
        ControlGet hwnd, Hwnd,, Windows.UI.Core.CoreWindow1, A
        if hwnd 
        {
            WinGet name, ProcessName, ahk_id %hwnd%
        }
    }
    return name
}

Answer 2

Photos는 명확하지 않은 또 다른 실행 파일을 호출하는 이상한 앱입니다.

이것은 테스트되었으며 작동합니다.

#IfWinActive, ahk_exe ApplicationFrameHost.exe
Left::Send {WheelUp}
Right::Send {WheelDown}

응용 프로그램 프레임 호스트는 특정 응용 프로그램을 프레임에 표시하도록 설계된 Windows 서비스입니다. 이 일반 실행 파일의 작동 방식을 수정하면 다른 Windows 응용 프로그램에 영향을 미칠 수 있습니다.

---

또 다른 가능성은 실행 파일 대신 "Photos"라는 문자열이 포함된 제목을 사용하는 것입니다.

SetTitleMatchMode, 2
#IfWinActive, Photos
Left::Send {WheelUp}
Right::Send {WheelDown}