여러 열의 비어 있지 않은 마지막 셀 값을 연결하는 방법

Question

여러 열에서 비어 있지 않은 마지막 셀 값을 깔끔하게 가져오는 방법, 즉 예상 값이 녹색으로 강조 표시되는 방법을 알고 싶습니다.

적용하여 열의 비어 있지 않은 마지막 셀을 얻는 방법을 알고 있습니다.

=IFERROR(LOOKUP(2,1/(INDIRECT("A1:A"&ROW())<>""),INDIRECT("A1:A"&ROW())),"")

그런 다음 적용하여 여러 열을 결합합니다.

=TEXTJOIN("",TRUE,G4:L4)

나는 다음과 같은 몇 가지 가능한 방법을 생각해 보았습니다.

1. 소스 데이터를 2D 배열에서 1D 배열로 변환하고 배열 수식으로 반환합니다.
2. 경우 배열을 사용하십시오.
3. 열 대신 행별로 반복합니다.

하지만 깔끔한 공식이 생각나지 않고 제대로 작동하지도 않습니다.

어떤 도움이라도 주시면 감사하겠습니다. 감사합니다.

Answer 1

한 행에 대해 다음을 수행할 수 있습니다.

1. 비어 있지 않은 셀에 대한 필터

2. 가장 오른쪽 열을 가져 가라.

   =LET(r,A4:F4,TAKE(FILTER(r,r<>""),-1))

유출된 단일 수식에서 이 작업을 수행하려면 해당 계산을 BYROW에 넣으면 됩니다.

=LET(d,A4:F16,BYROW(d,LAMBDA(r,TAKE(FILTER(r,r<>""),-1))))

편집: 텍스트 조인을 적용하려면 다음을 사용할 수 있습니다.

=LET(
    d, A4:F16,
    BYROW(
        d,
        LAMBDA(r,
            LET(
                lastletter, TAKE(FILTER(r, r <> ""), -1),
                position, XMATCH(lastletter, r),
                seqend, CODE(INDEX(lastletter, 1, 1)),
                seqstart, INDEX(seqend - position + 1, 1, 1),
                seq, SEQUENCE(seqend - seqstart + 1, , seqstart),
                TEXTJOIN("", TRUE, CHAR(seq))
            )
        )
    )
)