조판 삼각측량

Question

49페이지에이 메모토러스의 삼각측량에 대한 다음 다이어그램이 나타납니다.

제가 LyX에서 일한다는 사실을 기억하세요.

1. 이 아름다운 다이어그램을 재현하는 코드를 줄 수 있는 사람이 있나요?
2. 그러한 다이어그램을 만드는 방법은 어디서 배울 수 있나요?

추가됨:

또한 다음 다이어그램을 생성하는 코드도 마음에 듭니다.

Answer 1

여기 스타터가 있습니다메타포스트, 관련 하위 요소로 도면을 구성하는 한 가지 방법을 보여줍니다.

prologues := 3;
outputtemplate := "%j%c.eps";

beginfig(1);

picture t[], c;

z0 = origin;
z1 = 55 right rotated -5;
z2 = 60 right rotated 60;
z3 = 65 right rotated 20;

c = image(fill fullcircle scaled 3 withcolor background; draw fullcircle scaled 3;);
t1 = image(draw c shifted z1;);
t2 = image(
  draw z1--z2; 
  draw c shifted z1; 
  draw c shifted z2;
);
t3 = image(
  fill z0--z1--z2--cycle withcolor .9[red,white];
  draw z0--z1--z2--cycle;
  draw c shifted z0; 
  draw c shifted z1; 
  draw c shifted z2;
);
t4 = image(
  fill z0--z1--z2--cycle withcolor .9[red,white];
  fill z3--z1--z2--cycle withcolor .7[red,white];
  draw z0--z3 dashed withdots scaled .3 withcolor .7 white;
  draw z0--z1--z2--cycle; draw z1--z3--z2;
  draw c shifted z0; 
  draw c shifted z1; 
  draw c shifted z2;
  draw c shifted z3;
  );

for i=1 upto 4:
  draw t[i] shifted(80i-80,0);
endfor

endfig;
end.