☰

Active Directory 필드를 사용하여 Exchange 2003에서 서명 정책 시행

tag-icon • tag-icon active-directory exchange outlook
Active Directory 필드를 사용하여 Exchange 2003에서 서명 정책 시행

우리 조직에서는 이름, 직위, 연락처 세부 정보 및 사무실 위치를 기반으로 하는 모든 사용자에 대한 표준 서명 블록이 필요하다고 결정했으며 이러한 모든 정보는 Active Directory에 저장되어 있습니다.

Active Directory 필드를 기반으로 Outlook/Exchange 2003 서명을 자동으로 생성하는 깔끔한 솔루션을 찾은 사람이 있습니까?

답변1

나는 오랜 고객이자 팬이다.Exclaimer 메일 유틸리티.

Exchange 서버에 위치하며 고정식 적용 여부를 결정하는 사용자 정의 가능한 규칙이 많이 있습니다. 외부로 전송되는 모든 이메일의 상단에 회사 로고를 추가하고 하단에는 사람 이름, 직위, 다양한 전화번호를 모두 Active Directory에서 가져옵니다.

저는 지원 서비스를 한 번밖에 이용하지 않았지만 그들은 매우 친절하고 지식이 풍부하며 문제를 매우 신속하게 해결해 주었습니다.

답변2

나는 내가 쓴 대본으로 매우 행운을 누렸다. 다양한 AD 필드를 보이지 않는 Word 문서에 기록한 다음 이를 기본 및 회신 서명으로 Outlook 2007에 복사합니다.

로그인할 때마다 자동으로 실행되는 방식에서 벗어났습니다. 아주 드물게 사용자가 컴퓨터에 처음 로그인할 때 마법사를 거치지 않으면 Outlook을 열 수 없는 문제가 발생합니다. 현재로서는 "이메일 서명 재설정"이라는 사용자 데스크탑에 대한 바로가기를 푸시하는 GPO입니다. 또한 이를 통해 사용자는 매번 재정의하지 않고도 기본이 아닌 서명을 가질 수 있습니다.

On Error Resume Next

Set objSysInfo = CreateObject("ADSystemInfo")

strUser = objSysInfo.UserName
Set objUser = GetObject("LDAP://" & strUser)

strName = objUser.FullName
strTitle = objUser.Title
strDepartment = objUser.Department
strCompany = objUser.Company
strPhone = objUser.telephoneNumber
strFax = objUser.faxNumber

strStreet = objUser.StreetAddress
strCity = objUser.L
strState = objUser.St
strPOBox = objUser.postalCode

strFirstName = objUser.givenName
strInitials = objUser.initials
strLastName = objUser.sn
If strInitials = "" Then
    strFullName = strFirstName & " " & strLastName
Else
    strFullName = strFirstName & " " & strInitials & ". " & strLastName
End If

Set objWord = CreateObject("Word.Application")

Set objDoc = objWord.Documents.Add()
Set objSelection = objWord.Selection
objSelection.Style = "No Spacing" 
objSelection.Font.Name = "Calibri"
objSelection.Font.Size = "11"

Set objEmailOptions = objWord.EmailOptions
Set objSignatureObject = objEmailOptions.EmailSignature

Set objSignatureEntries = objSignatureObject.EmailSignatureEntries

objSelection.TypeParagraph()
objSelection.TypeText "Sincerely,"
objSelection.TypeParagraph()
objSelection.TypeParagraph()
objSelection.TypeText "ORGANIZATION NAME"
objSelection.TypeParagraph()
objSelection.TypeParagraph()
objSelection.TypeText strFullName & ", " & strTitle
'objSelection.TypeText strName & ", " & strTitle
objSelection.TypeParagraph()
objSelection.TypeParagraph()
objSelection.TypeText strStreet
objSelection.TypeParagraph()
objSelection.TypeText strCity & ", " & strState & " " & strPOBox
objSelection.TypeParagraph()
objSelection.TypeText "Desk: " & strPhone
objSelection.TypeParagraph()
objSelection.TypeText "Fax:    " & strFax
objSelection.TypeParagraph()

'Hyperlink below
objDoc.Hyperlinks.Add objSelection.Range, "www.yoursitename.com", "", "", "www.yoursitename.com", ""

objSelection.TypeParagraph()
objSelection.TypeParagraph()

'Picture below
Set objShape = objSelection.InlineShapes.AddPicture("\\fileserver\path\to\image.BMP")

Set objSelection = objDoc.Range()

objSignatureEntries.Add "AD Signature", objSelection
objSignatureObject.NewMessageSignature = "AD Signature"
objSignatureObject.ReplyMessageSignature = "AD Signature"

objDoc.Saved = True
objWord.Quit

질문이 있으시면 알려주세요!

관련 정보