☰

awk의 if else 문을 사용하여 기존 열을 기반으로 새 열을 만듭니다.

tag-icon • tag-icon linux debian text-processing awk columns
awk의 if else 문을 사용하여 기존 열을 기반으로 새 열을 만듭니다.

700만 개가 넘는 행(실제로는 20개 이상의 열)이 있는 데이터세트가 있고 새 열(데이터세트 예에는 5개 열이 있음)을 생성하려고 하므로 숫자 6이 됩니다. 내 데이터세트에 헤더가 있습니다.

조건은 다음과 같아야 합니다. 열 1의 값이 열 3의 값보다 크면 새 열은 열 1의 값을 가져야 합니다. 그렇지 않으면 "1에서 열 1의 값을 뺀 값"이 있어야 합니다.

이것을 시도했지만 작동하지 않습니다.

awk '{ if ($1 > $3) $6 == $1}; else $6 == 1-$1}' test.txt > test2.txt

데이터세트(예):

col1 col2 col3 col4 col5
1 3 4 string string
4 2 1 string string

1행의 경우 col6은 1-1 =이어야 하고 0, 2행의 경우 col6은 이어야 합니다 4.

답변1

==두 피연산자의 값이 같은지 여부를 확인하고 =오른쪽 피연산자의 값을 왼쪽 피연산자에 할당합니다. 다음 줄이 작동해야 합니다.

awk '{ if($1>$3) $6=$1; else $6=1-$1; print $0; } ' test01 > test02

또는:

awk '$1>$3{ $6=$1; print $0; } $1<$3{ $6=1-$1; print $0; }' test01 > test02

왜냐하면 awk다음과 같은 방식으로 작동하기 때문입니다.

awk 'condition1{main1} condition2{main2} ... conditionN{mainN}' file.txt

조건이 주어지지 않으면 해당 메인이 항상 실행됩니다.

답변2

이 시도. ==로 교체 =하고 중괄호를 추가하면 됩니다 .

awk '{ if ($1 > $3){ $6=$1 }else{ $6=1-$1 } print }' test.txt >test2.txt

답변3

$ awk 'NR==1 { $0 = $0 OFS "newcol"; print; next }
             { $(NF+1) = $1      }
    $1 <= $3 { $NF     = 1 - $NF } 1' file
col1 col2 col3 col4 col5 newcol
1 3 4 string string 0
4 2 1 string string 4

스크립트 awk가 새 열 머리글을 추가하고 출력하면 다른 행에 대한 새 열 값을 계산하기 시작합니다.

먼저 1열의 값으로 설정하여 값을 계산하고, 1열이 3열보다 작거나 같으면 1에서 뺍니다. 1끝에 1이 있으면 수정된 레코드(행)가 인쇄됩니다.

$(NF + 1)("마지막 필드 다음의 필드") 에 값을 할당하면 현재 행에 추가 열이 추가되고 증가 NF(현재 레코드의 필드 수)도 추가됩니다.

명시적인 if-statement를 사용하여 이 작업을 수행할 수도 있습니다.

awk 'NR==1 { $0 = $0 OFS "newcol"; print; next }
    { if ($1 > $3) $(NF+1) = $1; else $(NF+1) = 1 - $1 } 1' file

관련 정보