☰

Existe um programa para analisar estatísticas do servidor NTP?

tag-icon • tag-icon 12.04 ntp
Existe um programa para analisar estatísticas do servidor NTP?

Estou executando o Ubuntu 12.04 e tenho o servidor NTP em execução, aparentemente OK. Eu executo o servidor Meinberg NTP em minhas duas caixas do Windows 7 e uso o monitor de servidor associado para acompanhar o que está acontecendo.

Existe um monitor Linux semelhante, de preferência um com uma GUI que possa me mostrar como meu relógio está se comportando, etc?

Responder1

Não é uma resposta precisa à sua pergunta, mas vejo que você mencionou que agora usa um script gnuplot que analisa/var/log/ntp/loopstats. Eu faço o mesmo e abaixo está aquele que eu mesmo uso.

Se alguém estiver fazendo algo melhor, também ficaria curioso.

#! /usr/bin/gnuplot
# Remember to check you have these lines in /etc/ntp.conf and that ntpd is actually running:
#    statsdir /var/log/ntpstats/
#    statistics loopstats peerstats clockstats
#    filegen loopstats file loopstats type day enable
#    filegen peerstats file peerstats type day enable
#    filegen clockstats file clockstats type day enable

# Resolution: fullscreen
set term x11 size `xrandr | awk '/\*/{sub(/x/,",");print $1; exit}'`
set grid
set bars 0.4
set y2tics
set y2range [0:]
set ytics nomirror
set xdata time
set timefmt "%s"
set format x "%T"
set title "NTP statistics"
set ylabel "Clock offset / Roundtrip delay (ms)"
set y2label "Frequency offset (seconds per day)"
set xlabel "Time of day"
local_time = `date +%s --utc -d "12:00:00 $(date +%z)"`
utc_time   = `date +%s --utc -d "12:00:00"`
localdifferencefromUTC = utc_time - local_time
timeoffsettoday = `date +%s --utc -d "today 0:00"` + localdifferencefromUTC
plot \
  "/var/log/ntpstats/loopstats" u ($2+timeoffsettoday):($3*1000):($5*1000/2) t "Clock offset" w errorlines lt 1 lw 2 pt 187, \
  "/var/log/ntpstats/peerstats" u ($2+timeoffsettoday):($6*1000):($8*1000/2) t "Roundtrip delay" w errorbars lt 26 pt 26,\
  "/var/log/ntpstats/loopstats" u ($2+timeoffsettoday):($4*0.0864):($6*0.0864/2) axes x1y2 t "Frequency offset" w errorline lt 7 pt 65,\
  0 w l lt -1
pause mouse close

Responder2

ntp.org oferece muitoslinksàs ferramentas de monitoramento em seu site

informação relacionada