☰

Resultado:

tag-icon • tag-icon awk
Resultado:

Preciso imprimir a diferença entre o valor máximo e mínimo de um registro ($3) para cada ID único ($1).

arquivo de dados

Id str mt no  
101 2 550 1
101 3 540 2
101 3 350 3
101 4 600 4
101 4 700 5
102 1 400 1
102 4 500 2
102 4 350 3
102 3 550 4
103 3 500 1
103 4 300 2
103 3 550 3

saída

    Id str mt no diff 
    101 2 550 1 350
    101 3 540 2 350
    101 3 350 3 350
    101 4 600 4 350
    101 4 700 5 350
    102 1 400 1 200
    102 4 500 2 200
    102 4 350 3 200 
    102 3 550 4 200
    103 3 500 1 250
    103 4 300 2 250
    103 3 550 3 250

Responder1

estranhoabordagem usando matrizes multidimensionais eum tipofunção:

awk 'NR==1{ h=$0; } NR>1 { b[NR]=$0;a[$1][length(a[$1])+1]=$3; }
    END { print h,"diff";
        for (i in a) { asort(a[i]) } 
        for (k=2;k<=NR;k++) { 
            split(b[k],sep); max=length(a[sep[1]]); 
            print b[k],a[sep[1]][max] - a[sep[1]][1]
        } 
    }' file

A saída:

Id str mt no   diff
101 2 550 1 350
101 3 540 2 350
101 3 350 3 350
101 4 600 4 350
101 4 700 5 350
102 1 400 1 200
102 4 500 2 200
102 4 350 3 200
102 3 550 4 200
103 3 500 1 250
103 4 300 2 250
103 3 550 3 250

Responder2

Aqui está uma versão "pedagógica":

awk '
NR == 1 {
  header=$0
}
NR > 1 {
  line[NR]=$0
  if($4==1) {
    min[$1]=max[$1]=$3
  }
  else {
    if(min[$1]>$3) min[$1]=$3
    if(max[$1]<$3) max[$1]=$3
  }
}
END {
  printf("%s diff\n",header)
  for(i=2;i<=NR;i++) {
    split(line[i],e)
    printf("%s %d\n",line[i],max[e[1]]-min[e[1]])
  }
}
' datafile > output

Supondo que a coluna id esteja garantidamente ordenada, aqui está uma versão mais rápida que também usa muito menos memória:

awk 'function f() {for(i in r) printf("%s %d\n",r[i],u-l); delete r}
NR == 1 {printf("%s diff\n",$0)}
NR > 1 {if($4==1) {f(); l=u=$3}
  else {if(l>$3)l=$3; if(u<$3)u=$3}
  r[$4]=$0 }
END {f()}
'  datafile > output

Ambos os scripts geram a saída solicitada e funcionam com implementações awk compatíveis com POSIX, ou seja, não requerem extensões GNU awk como asort.

Responder3

perl -lane '
     push @A, $_; next if $. == 1; ($a, $b) = @F[0,2];

     $b > ($M{$a} // -Inf)  and $M{$a} = $b;
     $b < ($m{$a} // +Inf)  and $m{$a} = $b;

     END{$,=$";
        print shift @A, q/diff/;
        ($a) = /\d+/g, print $_, $M{$a} - $m{$a} for @A;
     }
' datafile

Resultado:

Id str mt no diff
101 2 550 1 350
101 3 540 2 350
101 3 350 3 350
101 4 600 4 350
101 4 700 5 350
102 1 400 1 200
102 4 500 2 200
102 4 350 3 200
102 3 550 4 200
103 3 500 1 250
103 4 300 2 250
103 3 550 3 250

Responder4

Aqui está uma solução de duas passagens

awk -f runawk first_pass=1 file first_pass=0 file

onde o conteúdo de runawkestá

FNR == 1 && /^Id/{
  if (!first_pass) print
  next
}
first_pass{
  if (!($1 in max)){
    min[$1] = max[$1] = $3
    next
  }
  max[$1] = $3 > max[$1]? $3: max[$1]
  min[$1] = $3 < min[$1]? $3: min[$1]
}
!(first_pass){
    print $1, $2, $3, max[$1] - min[$1]
}

informação relacionada