☰

Substitua o arquivo delimitado por vírgula por barra vertical, mas não remova vírgula ou aspas, etc., dentro do campo do qualificador de texto; no entanto, remova o qualificador de texto!

tag-icon • tag-icon shell-script sed regular-expression replace
Substitua o arquivo delimitado por vírgula por barra vertical, mas não remova vírgula ou aspas, etc., dentro do campo do qualificador de texto; no entanto, remova o qualificador de texto!

Meu arquivo é um arquivo delimitado por vírgula e o qualificador de texto é ~, mas meu requisito é localizar e substituir o arquivo delimitado por vírgula por |(pipe) arquivo delimitado e remover o qualificador de texto ~ sem nada, no entanto, não devo remover aspas ou aspas duplas ou qualquer caractere especial nos dados presentes no qualificador de texto. por exemplo: ~abc",~ eu preciso disso como abc",

Abaixo está o conteúdo do meu arquivo de origem e a maneira como espero que seja a saída ou o arquivo manipulado.

Arquivo fonte:

364034,2015652205,26722,2015,4,~C25753-4~,~TC25753,~,~2WD Double Cab 144.2" SLT,~,~Y~,40506.16,43555.00,1095.00,~043,005,006,007,003,008,016,041,012,029,068,027,028,033~,3,~2WD Double Cab 144.2"~,~SLT~,6,4,~N~,~S~,~N~,~S~,~N~,~N~,~N~,~~,~ ~,~Confirmed~,~w2015k65m22t5~,~Sierra 2500HD~,~Double Cab Standard Box 2-Wheel Drive SLT~,~Rear Wheel Drive~,~Extended Cab Pickup - Standard Bed~

Após a limpeza, preciso do arquivo assim:

364034|2015652205|26722|2015|4|C25753-4|TC25753,|2WD Double Cab 144.2" SLT,|Y|40506.16|43555.00|1095.00|043|005|006|007|003|008|016|041|012|029|068|027|028|033|3|2WD Double Cab 144.2"|SLT|6|4|N|S|N|S|N|N|N|| |Confirmed|w2015k65m22t5|Sierra 2500HD|Double Cab Standard Box 2-Wheel Drive SLT|Rear Wheel Drive|Extended Cab Pickup - Standard Bed

Tentei sed -i -e com várias opções, mas a saída não está 100% correta.

Tentei seguir mas não está dando o resultado certo que eu queria

sed -i -e 's/,~/|/g' file_name
sed -i -e 's/~,/|/g' file_name
sed -i -e 's/~//g' file_name
sed -i -e 's/\([0-9],[0-9]\)/|/g' file_name
sed -i -e 's/\r//g' file_name

Responder1

ESC=$(printf '\033')
RED="${ESC}[0;31m"
 NC="${ESC}[0m"

sed -e '
   /./!b
   /[^[:space:]]/!b

   s/.*/\
&,/

   :loop
      h
      s/\(\n\),/|\1/;                                                  # An empty field
      s/\(\n\)\([+-]\{0,1\}[.][0-9]\{1,\}\),/\2|\1/;                   # +-.NNN
      s/\(\n\)\([+-]\{0,1\}[0-9]\{1,\}\([.][0-9]*\)\{0,1\}\),/\2|\1/;  # +-NNN.MMM +-NNN. +-NNN
      s/\(\n\)~\([0-9][0-9]*\),/\2|\1/;                                # ~NNN
      s/\(\n\)\([0-9][0-9]*\)~,/\2|\1/;                                # NNN~
      s/\(\n\)~\([^~]*\)~,/\2|\1/;                                     # ~...~
      x;G
      /^\(.*\)\n\1$/{
         g;'"s/\n\([^,]*\)/${RED}\1${NC}/"'
         i\
***'"${RED}ERROR${NC}"'*** Unable to process the field shown colored.\
\
Cause of error: What this means is that this particular field is not \
\
           Fix: You should add to the sed code in the :loop label to \
                digest the able to be processed by the sed code as it stands.\
\
The record with the offending field shown colored red:\

         q
      }
      g; # all clear: recover and carry on...
   /\n$/!bloop

   s/..$//
' csv.data

Trabalhando

  • Baseamos a solução nos vários tipos de campos.
  • Pule linhas vazias ou em branco.
  • Acrescente um "," para simplificar o regex usado, iremos retirá-lo no final.
  • Para dar o pontapé inicial, colocamos um marcador, \n, no início da linha. Este marcador viajará da esquerda para a direita, saltando um campo processado uma vez.
  • A ação começa no do-whileloop, em cujo corpo processamos um campo por vez. O início do campo é sinalizado \ne processamos as diversas variedades de campos que podem ocorrer. Sempre, trazemos o campo processado para a esquerda \ne substituímos o ,por a |.
  • O loop para quando o marcador \natinge o final da linha /\n$/e então retiramos o marcador e também o manequim que ,colocamos no início.

Resultados

364034|2015652205|26722|2015|4|C25753-4|TC25753,|2WD Double Cab 144.2" SLT,|Y|40506.16|43555.00|1095.00|043|005|006|007|003|008|016|041|012|029|068|027|028|033|3|2WD Double Cab 144.2"|SLT|6|4|N|S|N|S|N|N|N|| |Confirmed|w2015k65m22t5|Sierra 2500HD|Double Cab Standard Box 2-Wheel Drive SLT|Rear Wheel Drive|Extended Cab Pickup - Standard Bed

Responder2

Eu sugeriria usar um analisador CSV dedicado, como o do PerlTexto::CSV

perl -MText::CSV -lne '
    BEGIN{ $csv = Text::CSV->new({ quote_char => "~" , escape_char => "~" , allow_whitespace => 1}) } 
    print join "|", $csv->fields() if $csv->parse($_)
  ' file_name
364034|2015652205|26722|2015|4|C25753-4|TC25753,|2WD Double Cab 144.2" SLT,|Y|40506.16|43555.00|1095.00|043,005,006,007,003,008,016,041,012,029,068,027,028,033|3|2WD Double Cab 144.2"|SLT|6|4|N|S|N|S|N|N|N|| |Confirmed|w2015k65m22t5|Sierra 2500HD|Double Cab Standard Box 2-Wheel Drive SLT|Rear Wheel Drive|Extended Cab Pickup - Standard Bed

informação relacionada