Teste condicional para existência de arquivos e tipos de arquivos específicos em zsh

Question

Quero verificar no diretório atual a existência de arquivos com extensões abc, bakou tmp,ouum arquivo chamado tmpout.wrk. Não consigo fazer isso (eventualmente parte de uma função) funcionar no zsh. Ele é executado, mas não consegue detectar corretamente.

if [[ -f *.(abc|bak|tmp) || -f tmpout.wrk ]]; then 
    echo 'true'; 
else 
    echo 'false'; 
fi

Answer 1

Para testar se o glob retorna pelo menos um arquivo, você pode fazer:

if ()(($#)) (*.(abc|bak|tmp)|tmpout.wrk)(NY1); then
  echo true
else
  echo false
fi

Para verificar se pelo menos um deles é um arquivo normal após a resolução do link simbólico, adicione o -. qualificador glob:

if ()(($#)) (*.(abc|bak|tmp)|tmpout.wrk)(NY1-.); then
  echo true
else
  echo false
fi

• ()(($#))é uma função anônima para a qual passamos o resultado dos globs. O corpo dessa função ( (($#))) apenas testa se o número de argumentos é diferente de zero.

• Ncomo um qualificador glob é ativado nullglobpara esse glob (faz com que o glob se expanda para nada quando não corresponde a nenhum arquivo)

• Y1limita a expansão a no máximo um arquivo. É uma otimização de desempenho.

• -faz com que o próximo qualificador global seja consideradodepoisresolução de link simbólico.

• .considera apenas arquivos regulares (portanto, aqui arquivos regulares ou links simbólicos eventualmente resolvem para um arquivo normal, como o [ -f file ]comando faz).

Answer 2

DR

set -o extendedglob
if [[ -n *.(abc|bak|tmp)(#qN) || -f tmpout.wrk ]]; then

Caso contrário, através de alguns testes,

% [[ -f /etc/passwd ]] && echo yea
yea
% echo /etc/passw?
/etc/passwd
% [[ -f /etc/passw? ]] && echo yea
% 

Ok, o que está zshfazendo aqui?

% set -x
% [[ -f /etc/passw? ]] && echo yes
+zsh:13> [[ -f '/etc/passw?' ]]
% 

Essas aspas simples com certeza não vão dar em nada. Vamos pesquisar [[em man zshall... e depois pesquisar CONDITIONAL EXPRESSIONS... ah, aqui está algo sobre geração de nome de arquivo:

   Filename  generation is not performed on any form of argument to condi-
   tions.  However, it can be forced in any case where normal shell expan-
   sion  is  valid and when the option EXTENDED_GLOB is in effect by using
   an explicit glob qualifier of the form (#q) at the end of  the  string.
   A  normal  glob qualifier expression may appear between the `q' and the
   closing parenthesis; if none  appears  the  expression  has  no  effect
   beyond causing filename generation.  The results of filename generation
   are joined together to form a single word, as with the results of other
   forms of expansion.

   This  special  use of filename generation is only available with the [[
   syntax.  If the condition occurs within the [ or test builtin  commands
   then  globbing  occurs instead as part of normal command line expansion
   before the condition is evaluated.  In this case it may generate multi-
   ple words which are likely to confuse the syntax of the test command.

   For example,

          [[ -n file*(#qN) ]]

   produces  status  zero if and only if there is at least one file in the
   current directory beginning with the string `file'.  The globbing qual-
   ifier  N  ensures  that the expression is empty if there is no matching
   file.

Então, com isso em mente,

% [[ -f /etc/passw?(#q) ]] && echo yes
+zsh:14> [[ -f /etc/passwd ]]
+zsh:14> echo yes
yes
% exec zsh -l

E para o seu caso, contabilizando o caso em que pode não haver arquivos:

% mkdir dir
% cd dir
% touch blah.foo
% [[ -f *.(foo|bar|baz)(#q) ]] && echo yea
yea
% rm blah.foo
% [[ -f *.(foo|bar|baz)(#q) ]] && echo yea
zsh: no matches found: *.(foo|bar|baz)(#q)
% [[ -f *.(foo|bar|baz)(#qN) ]] && echo yea
% touch a.foo b.foo
% [[ -f *.(foo|bar|baz)(#qN) ]] && echo yea
% [[ -n *.(foo|bar|baz)(#qN) ]] && echo yea
yea
% 

(embora -napenas verifiquemos se os globs correspondem, não se os arquivos correspondentes são arquivos regulares).