Windows XP e posterior

Question

Em um arquivo em lote, preciso extrair mês, dia e ano do comando de data. Então usei o seguinte, que essencialmente analisa o comando Date para extrair suas substrings em uma variável:

set Day=%Date:~3,2%
set Mth=%Date:~0,2%
set Yr=%Date:~6,4%

Tudo isso é ótimo, mas se eu implantar esse arquivo em lote em uma máquina com configurações de região/país diferentes, ele falhará porque mês, dia e ano estão em locais diferentes.

Como posso extrair mês, dia e ano independente do formato da data?

Answer 1

Fonte: http://ss64.com/nt/syntax-getdate.html

Método 2 (cmd único)

_{ObterData.cmd}

@Echo off
:: Check WMIC is available
WMIC.EXE Alias /? >NUL 2>&1 || GOTO s_error

:: Use WMIC to retrieve date and time
FOR /F "skip=1 tokens=1-6" %%G IN ('WMIC Path Win32_LocalTime Get Day^,Hour^,Minute^,Month^,Second^,Year /Format:table') DO (
   IF "%%~L"=="" goto s_done
      Set _yyyy=%%L
      Set _mm=00%%J
      Set _dd=00%%G
      Set _hour=00%%H
      SET _minute=00%%I
)
:s_done

:: Pad digits with leading zeros
      Set _mm=%_mm:~-2%
      Set _dd=%_dd:~-2%
      Set _hour=%_hour:~-2%
      Set _minute=%_minute:~-2%

:: Display the date/time in ISO 8601 format:
Set _isodate=%_yyyy%-%_mm%-%_dd% %_hour%:%_minute%
Echo %_isodate%
pause

---

Método 1 (cmd+vb)

_{ObterData.cmd}

@Echo off
For /f %%G in ('cscript /nologo getdate.vbs') do set _dtm=%%G
Set _yyyy=%_dtm:~0,4%
Set _mm=%_dtm:~4,2%
Set _dd=%_dtm:~6,2%
Set _hh=%_dtm:~8,2%
Set _nn=%_dtm:~10,2%
Echo %_yyyy%-%_mm%-%_dd%T%_hh%:%_nn%

_getdate.vbs

Dim dt
dt=now
'output format: yyyymmddHHnn
wscript.echo ((year(dt)*100 + month(dt))*100 + day(dt))*10000 + hour(dt)*100 + minute(dt)

Answer 2

Windows XP e posterior

_getDate.cmd

@echo off
for /f "tokens=2 delims==" %%G in ('wmic os get localdatetime /value') do set datetime=%%G

set year=%datetime:~0,4%
set month=%datetime:~4,2%
set day=%datetime:~6,2%

echo %year%/%month%/%day%

_Saída

Answer 3

Eu sei que não é exatamente o que você pediu, mas eu uso a porta Windows do dateaplicativo Linux a partir de um comando dentro do arquivo em lote e depois atribuo o resultado a uma variável.

Ainda não encontrei uma maneira de obter a data de maneira confiável usando apenas comandos em lote.

Answer 4

Embora você esteja certo de que o VS 2008 gera um arquivo em lote, você pode executar praticamente qualquer programa que desejar, incluindo scripts Powershell e outros programas.

Editar:

Aqui estão algumas perguntas semelhantes:

https://stackoverflow.com/questions/1051845/visual-studio-2008-professional-build-process https://stackoverflow.com/questions/3049369/embed-application-compilation-time-stamp

Originalmente, eu ia mudar isso para SO. . .