☰

Converter Mathematica em PDF via linha de comando

tag-icon • tag-icon conversion batch mathematica mathematica-notebook
Converter Mathematica em PDF via linha de comando

Estou no Linux e gostaria de converter vários notebooks do Mathematica 8 em PDF.

Existe alguma maneira de convertê-los na linha de comando? Gostaria de escrever uma regra makefile para a conversão, para poder converter em lote muitos deles.

Responder1

Basicamente, não há como converter notebooks do Mathematica em PDFs sem invocar o frontend. Para imprimi-lo ou convertê-lo, primeiro você precisa abri-lo e uma tentativa ingênua de abrir um caderno a partir doLinha de comando do Mathematicaproduz o erro FrontEndObject::notavail

In[1]:= NotebookOpen["file.nb"]

FrontEndObject::notavail: 
   A front end is not available; certain operations require a front end.

Isso significa que você pode criar um notebook para fazer a conversão ou chamar o frontend pela linha de comando. Aqui está uma solução na forma de umRoteiro matemático- pode ser facilmente transformado em um Notebook ou arquivo de pacote.

Salve o código a seguir como nb2pdf, torne-o executável e coloque-o no diretório com os arquivos que deseja converter ou em algum lugar no seu caminho.

#!/usr/local/bin/MathematicaScript -script

(* Convert Mathematica notebooks to PDFs                              *)
(*   usage: nb2pdf file1.nb file2.nb etc...                           *)
(* outputs: file1.pdf file2.pdf etc...  into the current directoy     *)
(* If called with no filenames, this script                           *)
(*    will convert all notebook files in the current directory        *)

dir = Directory[];
files = {};
expandNb = False; (* Expand all cell groups in the Notebook *)

If[Length[$ScriptCommandLine] > 1, 
  Do[If[FileExistsQ[file], 
    AppendTo[files, file], 
    Print["File " <> file <> " does not exist"]],
    {file, Rest[$ScriptCommandLine]}],
  files = FileNames["*.nb"]];

With[{UFE = UsingFrontEnd},
 Do[nb = UFE@NotebookOpen[FileNameJoin[{dir, file}]];
  If[expandNb, UFE@SelectionMove[nb, All, Notebook]; 
               UFE@FrontEndExecute[FrontEndToken["SelectionOpenAllGroups"]]];
  UFE@NotebookPrint[nb, FileNameJoin[{dir, FileBaseName[file]<>".pdf"}]];
  UFE@NotebookClose[nb], {file, files}]]

Responder2

Algo que funciona com o Mathematica 13: https://knanagnostopoulos.blogspot.com/2023/01/convert-many-mathematica-notebooks-to.html

nb2pdf (){ for f in $@;do echo -n "Converting $f to pdf ... "; wolframscript -code nb=\"$f\"';FileConvert[nb, "PDF"];' ;done; } 

nb2pdf *.nb

informação relacionada