☰

Como altero o idioma de todos os slides do PowerPoint de uma vez?

tag-icon • tag-icon windows microsoft-office microsoft-powerpoint microsoft-powerpoint-2010
Como altero o idioma de todos os slides do PowerPoint de uma vez?

Quero alterar o idioma de revisão de todos os meus slides em um PowerPoint. Tentei definir o idioma através do menu Preferências de idioma, mas isso só muda para novos powerpoints.

Responder1

Para alterar o idioma dointeiroPowerPoint facilmente, abra oVisualizarguia e selecione oContornovisualizar.

Agora pressione

  • Ctrl+ Apara selecionar tudo.
  • Ferramentas→Linguagem→ Escolha seu idioma para definir.

Da mesma forma, enquanto você tiver tudo selecionado, você pode alterar outras coisas, como fontes, cores, etc. Embora, é claro, em muitos casos isso seja melhor feito alterando o slide mestre, uma apresentação que teve muitos editores pode ter muitos conjuntos de formatação 'rígidos' que se desvia do mestre subjacente e precisa ser redefinido para ser consistente. Você também pode redefinir slides individuais para o estilo mestre, mas isso também pode resultar na movimentação dos espaços reservados, o que pode ser indesejável em algumas situações.

PowerPoint 2013

  • Visualizar→Contorno→ selecione todos os slides (no menu esquerdo) via Ctrl+ A.
  • Análise→Linguagem→Definir idioma de revisão...→ Escolha seu idioma para definir.

Quanto a mim - PowerPointreiniciarfoi necessário. Provavelmente porque eu também mudeiEditando Idioma:

  • Análise→Linguagem→Definir idioma de revisão...→Preferências de idioma→Escolha os idiomas de edição.

Responder2

UsandoPowerPoint 2010Abri o menu Outline -

guia de contorno

Selecionei todo o texto (Ctrl+A), abri o menu de idiomas e configurei meu idioma de revisão

opção de idioma

E funcionou!

O menu de idiomas está localizado na guia da faixa de opções Revisão (após a guia Apresentação de slides e não visível na captura de tela).

Responder3

eu melhoreiA resposta de Inigopara fornecer uma versão recursiva que altera todos os itens para o idioma desejado.

Esta versão investigará recursivamente cada forma que seja um tipo de grupo. Algumas experiências sugerem que msoGroupe msoSmartArtsão os tipos de grupo - sinta-se à vontade para adicionar itens a essa lista se encontrar outros tipos de formas que possam conter objetos de texto.

Sub ChangeProofingLanguageToEnglish()
    Dim j As Long, k As Long
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDEnglishUK

    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), _
              languageID
        Next k
    Next j
End Sub


Sub ChangeAllSubShapes(targetShape As shape, languageID As MsoLanguageID)
    Dim i As Long

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

Responder4

Com base nas respostas de Inigo, Duncan, Maria e DomDev, isso funciona para formas, tabelas, grupos, SmartArt, agora e no futuro:

Sub ChangeProofingLanguageToFrench()
    Dim j, k As Integer
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDFrench

    'Loop all the slides in the document, and change the language
    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), languageID
        Next k
    Next j

    'Loop all the master slides, and change the language
    For j = 1 To ActivePresentation.SlideMaster.CustomLayouts.Count
        For k = 1 To ActivePresentation.SlideMaster.CustomLayouts(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.SlideMaster.CustomLayouts(j).Shapes(k), languageID
        Next k
    Next j

    'Change the default presentation language, so that all new slides respect the new language
    ActivePresentation.DefaultLanguageID = languageID
End Sub

Sub ChangeAllSubShapes(targetShape As Shape, languageID As MsoLanguageID)
    Dim i As Integer, r As Integer, c As Integer

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    If targetShape.HasTable Then
        For r = 1 To targetShape.Table.Rows.Count
            For c = 1 To targetShape.Table.Columns.Count
                targetShape.Table.Cell(r, c).Shape.TextFrame.TextRange.languageID = languageID
            Next
        Next
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

informação relacionada