☰

Recurso do Windows 7 ou freeware para manter uma janela sempre abaixo das outras

tag-icon • tag-icon windows-7 window ordering always-on-top
Recurso do Windows 7 ou freeware para manter uma janela sempre abaixo das outras

Alguns programas, por exemplo, GridMove e XNeat, permitem aos usuários manter uma determinada janela acima de outras janelas usando um comando "Always On Top". Existe uma maneira de fazer o inverso, ou seja, "Always At The Bottom" com qualquer comando do Windows 7 ou freeware, exceto tornando todas as outras janelas "Always On Top"?

Às vezes, é útil manter os programas de bate-papo (nos quais ocorre a digitação) abaixo de todas as janelas, com apenas a mensagem mais recente e o campo de entrada de texto visíveis nas lacunas das janelas, sem que o restante da interface do programa de bate-papo ocupe o espaço.

Responder1

Há muito tempo, o Windows tinha um PowerToy (mais tarde no TweakUI) chamado X-Mouse que, entre outras coisas, suportava o antigo estilo X "foco segue o mouse", onde "foco" e "primeiro plano" não eram a mesma coisa. Não acredito mais que seja mantido (o último avistamento foi para WinXP).

Embora eu não a tenha usado extensivamente, a ferramenta gratuita de script do WindowsAutoITpode fazer o que quiser com um pequeno script:

#include <WinAPI.au3>
#include <Constants.au3>
#include <WindowsConstants.au3>
#include <MenuConstants.au3>
#include <SendMessage.au3>

Local $hWnd,$flags,$regexp

Func MyExit() 
    MsgBox(0,"Drop Window","Quitting!",2) 
    Exit 0
EndFunc

$flags = BitOr($SWP_NOMOVE,$SWP_NOSIZE,$SWP_NOACTIVATE,$SWP_ASYNCWINDOWPOS,$SWP_NOSENDCHANGING) 

;; hot key to call exit: ALT + F11
HotKeySet("!{F11}","MyExit")

;; application window title
$regexp=".*Notepad$"

;; 10 second time out on first startup, 
$hWnd = WinWait("[REGEXPTITLE:" & $regexp & "]", "", 10)
;; or wait forever
;$hWnd = WinWait("[REGEXPTITLE:" & $regexp & "]")

If ($hWnd) Then
    ;; uncomment next line to maximize window first
    ;_SendMessage($hWnd,$WM_SYSCOMMAND,$SC_MAXIMIZE)

    _WinAPI_SetWindowPos($hWnd, $HWND_BOTTOM, 0, 0, 0, 0, $flags);

    While 1
        If WinWaitActive($hWnd,"",10) Then
            _WinAPI_SetWindowPos($hWnd, $HWND_BOTTOM, 0, 0, 0, 0, $flags);
        EndIf
        ;; check for new window
        $hWnd = WinWait("[REGEXPTITLE:" & $regexp & "]","",1) 

        ;; uncomment next 3 lines to quit if no window
        ;if (NOT $hWnd) Then
        ;    MyExit()
        ;EndIf

        Sleep(250)
    Wend
Else
    MsgBox(0,"Drop Window","No window title matching /" & $regexp & "/") 
EndIf

"topmost" é uma propriedade de janela persistente que o WM mantém, não há equivalente "bottom most", então temos que falsificá-la um pouco.

O loop While espera que o aplicativo obtenha o primeiro plano e, em seguida, coloca-o novamente enquanto mantém o foco do teclado. Às vezes, os pop-ups modais podem interferir nisso, mas devem ser bastante utilizáveis. O script continuará a ser executado em segundo plano após o término do programa assistido. Alt+F11 para sair a qualquer momento.

Altere $regexp para corresponder a "mIRC" ou algo assim. O procedimento acima irá lidar com segurança apenas com uma janela por vez. Leia a documentação do AutoIT para WinWait() para ver como combinar janelas que não sejam pelo título da janela.

Salve em dropwindow.au3 e execute-o com "autoit3 dropwindow.au3".

http://www.autoitscript.com/site/autoit/downloads/

Responder2

Se você possui um PC equipado com placa gráfica ATI Radeon, você pode usar o HydraGrid com os drivers e utilitários mais recentes da ATI, caso contrárioRevolução Winsplit.

informação relacionada