☰

Como colocar os itens de acordo com um título?

tag-icon • tag-icon text-processing awk
Como colocar os itens de acordo com um título?

Eu tenho mais de 5.000 linhas separadas por espaço como abaixo:

Item_A: Acou#1  Bla#5

Item_B: Acou#1  Elfa#2  Flq#2

Item_C: Acou#1  Bla#4   Elfa#2  Flq#2

Item_D: Agly#3  Bla#4   Elfa#2

Quero fazer uma tabela com cabeçalhos comuns para todos e quantidade de cada um em uma tabela conforme abaixo,

             Acou  Agly  Bla  Elfa  Flq

Item_A:      1     0     5    0     0

Item_B:      1     0     0    2     2

Item_C:      1     0     4    2     2

Item_D:      0     3     4    2     0

Eu costumava grep linhas contendo "Acou", depois "Bla" e assim por diante. Em seguida, edite no Excel para quantificá-los e concatene todos os arquivos separados em um arquivo. No entanto, demorou muito.

Responder1

BEGIN { OFS = "\t" }

# Collect headers from data
FNR == NR {
    for (i = 2; i <= NF; ++i)
        if (!($i in heads))
            heads[$i]
    next
}

# Output header
FNR == 1 {
    line = "Items"
    for (j in heads)
        line = line OFS j
    print line
}

{
    line = $1
    # Iterate through the header items, testing each field against it
    for (j in heads) {
        found = 0 # assume not found
        for (i = 2; !found && i <= NF; ++i)
            if ($i == j)
                found = 1 # matches header
        line = line OFS found
    }
    print line
}

Executando isso em seus dados (depois de remover as linhas vazias):

$ awk -f script.awk file file
Items   Acou#1  Bla#4   Bla#5   Elfa#2  Agly#3  Flq#2
Item_A: 1       0       1       0       0       0
Item_B: 1       0       0       1       0       1
Item_C: 1       1       0       1       0       1
Item_D: 0       1       0       1       1       0

Observe que você deve especificar o arquivo de dados de entrada duas vezes. Isso ocorre porque estamos digitalizando duas vezes. Na primeira varredura estamos coletando os itens de dados em cada linha (o FNR == NRbloco). Na segunda varredura, testamos cada item de dados coletado (os cabeçalhos) em relação aos dados de cada linha.

A saída é simplesmente 0se o campo no cabeçalho não estiver presente nos dados dessa linha e 1se estiver. Isso não ébastanteo que você pediu, então...

Uma variação que trunca os cabeçalhos no #e usa a parte após o #como dados a serem exibidos:

BEGIN { OFS = "\t" }

# Collect headers from data
FNR == NR {
    for (i = 2; i <= NF; ++i) {
        split($i, h, "#")
        if (!(h[1] in heads))
            heads[h[1]]
    }
    next
}

# Output header
FNR == 1 {
    line = "Items"
    for (j in heads)
        line = line OFS j
    print line
}

{
    line = $1
    # Iterate through the header items, testing each field against it
    for (j in heads) {
        found = 0 # assume not found
        for (i = 2; !found && i <= NF; ++i) {
            split($i, h, "#")
            if (h[1] == j)
                found = h[2] # matches header
        }
        line = line OFS found
    }
    print line
}

Executando:

$ awk -f script.awk file file
Items   Elfa    Bla     Acou    Agly    Flq
Item_A: 0       5       1       0       0
Item_B: 2       0       1       0       2
Item_C: 2       4       1       0       2
Item_D: 2       4       0       3       0

Observe que a ordem das colunas não é necessariamente ordenada (já que elas são armazenadas como chaves em um array associativo). Estou deixando como exercício para o leitor classificá-los.

Responder2

Se você não se importa em jogarConjunto de dados GNUna mistura, então você poderia simplesmente serializar as entradas e depois tabulá-las:

awk '
  {for (i=2;i<=NF;i++) {split($i,a,"#"); print $1,a[1],a[2]}}' OFS='\t' file | 
  datamash --filler=0 crosstab 1,2 count 3
    Acou    Agly    Bla Elfa    Flq
Item_A: 1   0   1   0   0
Item_B: 1   0   0   1   1
Item_C: 1   0   1   1   1
Item_D: 0   1   1   1   0

Alternativamente, com GNU awk (que permite matrizes multidimensionais):

gawk '
  BEGIN {
    OFS="\t";
    PROCINFO["sorted_in"] = "@ind_str_asc";
  }
  {
    for (i=2;i<=NF;i++) {
      split($i,a,"#"); 
      h[a[1]] = 1;
      t[$1][a[1]] += a[2];
    }
  } 
  END {
    for (j in h) printf("\t%s", j);
    printf "\n";
    for (i in t) {
      printf("%s",i);
      for (j in h) 
        printf("\t%d", j in t[i] ? t[i][j] : 0);
      printf "\n";
    }
  }' file
    Acou    Agly    Bla Elfa    Flq
Item_A: 1   0   5   0   0
Item_B: 1   0   0   2   2
Item_C: 1   0   4   2   2
Item_D: 0   3   4   2   0

informação relacionada