Como obtenho links magnéticos com o Deluge ou isso é possível?

Question

Dizem que não é mais compatível? Por que o botão de hash de informações está esmaecido?

Alguém sabe como obtenho links Magnet com o Deluge Web UI Client?

Aliás, minha versão do cliente Deluge é 1.3.5

Answer 1

De acordo comPergunte ao Ubuntu, o suporte magnético na WebUI foi adicionado na versão 1.3.4 em maio. Tem certeza de que está atualizado?

Answer 2

Clico com o botão direito do mouse no link magnético e em "Copiar endereço do link" ou similar e, em seguida, copio esse link para o dilúvio em "adicionar torrent".

Answer 3

Para Mac, usuário do GitHubSenhor-KaminaescreveuManipulador de ímã de dilúvio, uma solução alternativa do AppleScript. Instalado na pasta Aplicativos e executado uma vez para se associar aos magnet:links, esses URLs deverão abrir automaticamente no Deluge a partir de então.

on quit
    try
        tell application "System Events" to tell process "Deluge"
            activate
            set frontmost to true
            windows where title contains "Add Torrents"
            if result is not {} then perform action "AXRaise" of item 1 of result
        end tell
    end try
end quit

on open location this_URL
    try
        tell application "Finder" to set delugePath to POSIX path of (application file id "org.deluge" as string)
        set appExists to true
    on error
        set appExists to false
        display alert "Deluge.app must be installed in order to use this plug-in." as critical
        return
    end try
    set delugeArgument to quoted form of this_URL
    try
        tell application "Deluge" to activate
    end try
    do shell script (quoted form of (delugePath & "/Contents/MacOS/Deluge") & " add " & delugeArgument & "; return;")
    quit
end open location
tell application "Finder" to set thisPath to (POSIX path of (application file id "org.deluge.MagnetURIHandler" as string))
log thisPath
set lsToolRead to do shell script (quoted form of (thisPath & "/Contents/Resources/lstool") & " read url magnet")
if (lsToolRead contains "Magnet Handler.app") then
    display dialog "Magnet Handler is already the default application to handle magnet URIs" buttons {"OK"} with title "Notification" with icon POSIX file (thisPath & "/Contents/Resources/deluge_magnet.icns")
else
    try
        set dialogResult to display dialog "Magnet Handler has not been configured to handle magnet URIs.

Would you like to do this now?" buttons {"Yes", "No"} default button "Yes" cancel button "No" with title "Notification" with icon POSIX file (thisPath & "/Contents/Resources/deluge_magnet.icns")
    on error number -128
    end try
    try
        if button returned of dialogResult is "Yes" then
            do shell script (quoted form of (thisPath & "/Contents/Resources/lstool") & " write url magnet org.deluge.MagnetURIHandler")
            display dialog "Magnet Handler has now been configured as the default application to handle magnet URIs" buttons {"OK"} with title "Notification" with icon POSIX file (thisPath & "/Contents/Resources/deluge_magnet.icns")

        end if
    end try
end if
quit