☰

Obtenha o tamanho do disco/partição no arquivo em lote

tag-icon • tag-icon windows-7 windows batch disk-space
Obtenha o tamanho do disco/partição no arquivo em lote

Como conseguirtamanho totalde um disco ou partição (um disco rígido USB com 1 partição NTFS) em um arquivo em lote?
Prefiro não usar uma lógica que analise os arquivos recursivamente (aqueles com for /f), pois é uma unidade de 1 TB e pode levar muito tempo para determinar o tamanho.

Estou aberto para usar alguma pequena ferramenta de terceiros que retornará o tamanho do arquivo em lote.

PS: estou no Windows 7 x64 Ultimate

Responder1

Provavelmente existe uma maneira mais fácil de fazer isso, mas aqui está o que eu uso

Se tudo o que você deseja são os bytes, basta executar este comando, alterar T para a letra da unidade externa (para um liner no prompt de comando, altere %%para %e set space=para echo)

for /f "tokens=3 delims= " %%a in ('dir /-c T: ^| find "bytes free"') do set space=%%a

se você quiser pegar isso e simplificá-lo, primeiro defina diretrizes para cada tamanho

set divide=1073741824&&set size=gigabytes
if %space% lss 1073741824 set divide=1048576&&set size=megabytes
if %space% lss 1048576 set divide=1024&&set size=kilobytes
if %space% lss 1024 set divide=1&&set size=bytes

Em seguida, escreva um script VBS temporário, pois o lote não consegue lidar com a matemática

echo wsh.echo cdbl(%space%)/%divide% > %temp%\tmp.vbs

Execute-o, capture o resultado e exclua-o

for /f %%a in ('cscript //nologo %temp%\tmp.vbs') do set space=%%a
del %temp%.\tmp.vbs

Em seguida, o seguinte corta o resultado para duas casas decimais

for /f "tokens=1,2 delims=." %%a in ("%space%") do (
  set s1=%%a
  set s2=%%b
)
if not "%s2%"=="" (set space=%s1%.%s2:~0,2%) else (set space=%s1%)

Resultados de eco

echo Drive has %space% %size% free.

[EDITAR]

Paratotaltamanho, você pode usar o volume da lista do diskpart (mudar "%%a"=="T"para "%%a"=="driveletterhere")

for /f "tokens=3,6,7 delims= " %%a in ('echo list volume ^| diskpart') do if "%%a"=="T" set size=%%b && set size2=%%c

e bônus como você poderia calcular isso:

if [%size2%]==[TB] (
    set isBigEnough=1
) else if [%size2%]==[GB] (
    if %size% GTR 31 set isBigEnough=1
)
if not defined isBigEnough set isBigEnough=0

Responder2

Talvez tente df.exeo que está disponível emhttp://unxutils.sourceforge.net/e outros locais. Esta é uma cópia de uma ferramenta de linha de comando UNIX.

Você também deve conseguir obter o valor diretamente da Interface de Gerenciamento do Windows (WMI), embora minhas habilidades nessa área não sejam boas o suficiente para fornecer uma resposta direta.

fsutil volume diskfree c:fornecerá 3 linhas de saída que você provavelmente poderia usar findpara obter o resultado desejado.

Exemplo de saída:

Total # of free bytes        : 466333454336
Total # of bytes             : 972999880704
Total # of avail free bytes  : 466333454336

fsutil volume diskfree c: | find "Total # of bytes"fornece uma linha específica.

for /F "tokens=2 delims=:" %i in ('fsutil volume diskfree c: ^| find "Total # of bytes"') do @set USED=%i

fornece o número com um espaço anterior.

Para uma comparação:

@REM 32MB = 32*1024*1024 bytes
@set COMP=33554432

@REM Pull out the line containing the number of bytes USED
for /F "tokens=2 delims=:" %i in ('fsutil volume diskfree c: ^| find "Total # of bytes"') do @set USED=%i

@REM Drop the leading space character to just get the number so a numeric comparison is done
for /F "tokens=1 delims= " %i in ('echo %USED%') do @set USED=%i

@REM Tell me something useful
if %USED% lss %COMP% @echo "Used is less than 32MB"
if %USED% gtr %COMP% @echo "Used is greater than 32MB"

NOTA: fsutil requer direitos de administrador, portanto pode não funcionar em computadores bloqueados.

informação relacionada