☰

concatenando string no loop FOR no arquivo em lote

tag-icon • tag-icon windows command-line
concatenando string no loop FOR no arquivo em lote

Tenho um arquivo sfsview_monitor1.txtcom o seguinte conteúdo:

Total pages: 16320
Pages used: 142
Pages free: 16178

Eu quero a saída assim:

16320 142 16178

com o seguinte código não estou conseguindo:

@echo on 
 SETLOCAL EnableDelayedExpansion

SET myvar=
for /f "tokens=1-3" %%P in ('type c:\shafique\sfsview_monitor1.txt ^| FINDSTR /B /I "Total Pages"') do (
    SET myvar=%myvar% %%R
 )
echo %myvar%

alguém pode me apontar na direção certa?

Responder1

Na IMO, isso não precisa necessariamente ser tão complicado quanto a outra resposta parece.

Se essas forem as únicas linhas no arquivo de texto, você poderá usar o seguinte:

@echo off
set var=
setlocal enabledelayedexpansion
for /f "tokens=2 delims=:" %%a in (sfsview_monitor1.txt) do set var=!var!%%a
set var=!var:~1!
echo !var!
endlocal

Se as linhas estiverem presentes em locais aleatórios no arquivo de texto, você poderá usar o seguinte:

@echo off
set var=
setlocal enabledelayedexpansion
for /f "tokens=2 delims=:" %%a in ('findstr /c:"Total pages" /c:"Pages used" /c:"Pages free" sfsview_monitor1.txt') do set var=!var!%%a
set var=!var:~1!
echo !var!
endlocal

Você nem precisa da primeira versão, já que a segunda é mais genérica.

Se você nem se importa em armazenar os valores em uma variável e está simplesmente interessado na saída, os seguintes liners também servirão:

@for /f "tokens=2 delims=:" %%a in (sfsview_monitor1.txt) do @echo | set /p var=%%a

e

@for /f "tokens=2 delims=:" %%a in ('findstr /c:"Total pages" /c:"Pages used" /c:"Pages free" sfsview_monitor1.txt') do @echo | set /p var=%%a

Importante:Em ambas as versões de uma linha há um espaço obrigatório no final da linha! Além disso, como mencionado acima, você pode simplesmente ignorar a primeira versão e usar a segunda, já que a última é a mais genérica das duas.

Responder2

O valor de %myvar%dentro do forloop será sempre o valor que era antes do início do loop. Se você quiser usar a variável modificada, use !myvar!-a.

@echo on 
 SETLOCAL EnableDelayedExpansion

SET myvar=
for /f "tokens=1-3" %%P in ('type c:\shafique\sfsview_monitor1.txt ^| FINDSTR /B /I "Total Pages"') do (
    SET myvar=!myvar! %%R
 )
echo %myvar:~1%

Isso produzirá

16320 142 16178

A %myvar:~1%parte simplesmente remove o espaço que o loop for coloca no início do primeiro número.

Responder3

Experimente isto:

@echo off &setlocal
set "tf=%temp%%random%"
set "pt=Total pages"
set "pu=Pages used"
set "pf=Pages free"
(echo(%pt%&echo(%pu%&echo(%pf%)>"%tf%"

for /f "tokens=1,2delims=:" %%i in ('^<"sfsview_monitor1.txt" findstr /g:"%tf%"') do (
    if "%%i"=="%pt%" for /f %%a in ("%%j") do set "npt=%%a"
    if "%%i"=="%pu%" for /f %%a in ("%%j") do set "npu=%%a"
    if "%%i"=="%pf%" for /f %%a in ("%%j") do set "npf=%%a"
)
del "%tf%"
SET "myvar=%npt% %npu% %npf%"
echo(%myvar%

informação relacionada