☰

comparação recursiva do conteúdo dos diretórios pelo cmd windows xp para o arquivo de saída

tag-icon • tag-icon windows-xp command-line cmd.exe
comparação recursiva do conteúdo dos diretórios pelo cmd windows xp para o arquivo de saída

Desejo comparar dois diretórios e subdiretórios de arquivos recursivamente, sem instalação adicional no Windows XP. a árvore dos nomes das pastas e arquivos é a mesma, mas o conteúdo dos arquivos pode ser diferente. Existe alguma maneira de fazer isso? Obrigado!

Responder1

Algo assim deve funcionar, assumindo, como você disse, que a árvore de origem e de destino são iguais:

@ECHO OFF
set myrootfolder1=c:\stack\rootfolder1
set myrootfolder2=c:\stack\rootfolder2
set logfile=c:\stack\compare.log

type NUL > %logfile%

setlocal ENABLEDELAYEDEXPANSION

FOR /R %myrootfolder1% %%G IN (*.*) DO (
    set sourcefile=%%G
    set targetfile=!sourcefile:%myrootfolder1%=%myrootfolder2%!
    echo N | comp /A !sourcefile! !targetfile! | find "OK" > nul
    IF ERRORLEVEL 1 echo !sourcefile! and !targetfile! are different >>%logfile%
)

Isso renderizará um arquivo de log como este:

c:\stack\rootfolder1\file1.txt e c:\stack\rootfolder2\file1.txt são diferentes c:\stack\rootfolder1\sub1\file2.txt e c:\stack\rootfolder2\sub1\file2.txt são diferentes

Editar: não usei fcaqui porque foram relatados bugs no Windows XP quando o comando compara arquivos que diferem a cada 128 bytes de uma sequência de caracteres. Minha referência:http://support.microsoft.com/kb/953929/en-us

Mas siga os comentários da @Synetech para mais informações;) graças a ele!

Responder2

Obrigado GD, encontrei: pastas comparativas - dir1 e dir2 estão na unidade D. O arquivo logfile.txt para resultados comparáveis ​​também está na unidade D. no arquivo em lote:

  D:
setlocal enableextensions 
setlocal ENABLEDELAYED EXPANSION 
SETLOCAL ENABLEDELAYEDEXPANSION
set filename=logfile.txt
echo. 2>%filename%
cd dir1
(for /r %%i in (*) do set p=%%i&if exist "D:\dir2\!p:~8!" (FC "%%i" "D:\dir2\!p:~8!" | FIND "FC: no dif" > nul&IF ERRORLEVEL 1 (echo !!! file %%i is different >> d:\%filename%)) else (echo !!! file"D:\dir2\!p:~8!" not found >> d:\%filename%))>nul
cd ..\dir2
(for /r %%i in (*) do set p=%%i&if not exist "D:\dir1\!p:~8!"   (echo !!! file "D:\dir1\!p:~8!"  not found >> d:\%filename%))>nul
cd ..
start %filename%

Responder3

Escrevi este lote em DOS puro. Ele pode comparar duas pastas com subpastas e exibir mensagens visuais durante a comparação. É útil para pequenas árvores de pastas, para que você possa ver imediatamente os erros na tela do console enquanto a comparação é realizada.

Nota: A comparação será pausada se ocorrer um erro de comparação! Não produz um log de erros, porém é possível redirecionar o erro Echo para um arquivo de log e cortar o comando Pause.

Para árvores de pastas ou conteúdos grandes é melhor utilizar ferramentas específicas como ROBOCOPY ou similares que produzem Relatórios bem detalhados, tanto para cópia quanto para comparação.

@Echo OFF
echo.
echo  Compares Files in two or more Folders or Paths
echo ================================================
echo.

set /P Src= Digit or Paste HERE Path n.1 : 
::set Src=YourPath
echo.
set /P Dst= Digit or Paste HERE Path n.2 : 
::set Dst=YourPath
echo.
PAUSE
echo.

SETLOCAL EnableDelayedExpansion

FOR /R "%Src%" %%A IN (*.*) DO (
  set SFold="%%A"
  set TFold=!SFold:%Src%=%Dst%!
  set P1="%%~dpA"

  if "!P2!" EQU "" set P2=!P1!
  if "!P1!" NEQ "!P2!" echo ----------------------------------------------------- Compare Folder is Changed & echo.
  FC !SFold! !TFold!
  if !ERRORLEVEL! NEQ 0 echo. - ERROR - ==================================================================== & PAUSE
  set P2=!P1!
)
echo.
echo ====================================
echo      COMPARE TERMINATED . . . .
echo ====================================
echo.
PAUSE

informação relacionada