☰

Encontrando Valores Únicos em 3 Colunas

tag-icon • tag-icon microsoft-excel-2010
Encontrando Valores Únicos em 3 Colunas

Eu tenho 3 colunas no Excel. Quero encontrar valores únicos nas colunas A, B e C.

Então:

  1. olhando na coluna A, quero encontrar os valores exclusivos que não estão em B ou C.
  2. olhando na coluna B, quero encontrar valores exclusivos que não estão na coluna A ou C.
  3. olhando na coluna C, quero encontrar valores exclusivos que não estão na coluna A ou B.

Isso é o que coloquei na coluna A

=IF(OR(MATCH(A3,$B$3:$B$631,0),(MATCH(A3,$C$3:$C$408,0))),"Match",A3)

Isso é o que coloquei na coluna B

=IF(OR(MATCH(B3,$A$3:$A$857,0),(MATCH(B3,$C$3:$C$408,0))),"Match",B3)

Isso é o que coloquei na coluna C

=(IF(OR(MATCH(C3,$A$3:$A$857,0),(MATCH(C3,$B$3:$B$631,0))),"Match",C3)

Isso me dá valores duplicados nas três colunas que preciso que sejam exclusivas. Talvez eu esteja apenas tornando isso muito complicado. Alguma ideia de como fazer isso?

O exemplo da tabela:

A   B   C
1   2   2
2   3   3
3   7   7
4   8   11
5   9   12
6   10  13

Neste caso, quero o # exclusivo em cada coluna. Portanto, para a coluna A os valores únicos que não estão nas colunas B ou C são = para 1,4,5,6. Na coluna B os valores únicos, que não estão em A ou C, são =8,9, 10. Na coluna C os valores únicos, que não estão em B ou C são = 11, 12, 13. Quero fazer um fórmula nas colunas D, E, F para essas três fórmulas.

ABC 1 2 2 2 3 3 3 7 7 4 8 11 5 9 12 6 10 13

Neste caso, quero o # exclusivo em cada coluna. Portanto, para a coluna A os valores únicos que não estão nas colunas B ou C são = para 1,4,5,6. Na coluna B os valores únicos, que não estão em A ou C, são =8,9, 10. Na coluna C os valores únicos, que não estão em B ou C são = 11, 12, 13. Quero fazer um fórmula na coluna D, E, F para essas três fórmulas.

Responder1

Você pode usar uma fórmula de matriz † como a seguinte em D1:

=IFERROR(INDEX($A$1:$A$6,SMALL(IF(ISERROR(MATCH($A$1:$A$6,$B$1:$B$6,0))*ISERROR(MATCH($A$1:$A$6,$C$1:$C$6,0)),ROW($A$1:$A$6)),ROW())),"")

As fórmulas nas outras colunas são semelhantes:

E1:

=IFERROR(INDEX($B$1:$B$6,SMALL(IF(ISERROR(MATCH($B$1:$B$6,$A$1:$A$6,0))*ISERROR(MATCH($B$1:$B$6,$C$1:$C$6,0)),ROW($B$1:$B$6)),ROW())),"")

F1:

=IFERROR(INDEX($C$1:$C$6,SMALL(IF(ISERROR(MATCH($C$1:$C$6,$A$1:$A$6,0))*ISERROR(MATCH($C$1:$C$6,$B$1:$B$6,0)),ROW($C$1:$C$6)),ROW())),"")

E da sua tabela de exemplo, recebo isto:

insira a descrição da imagem aqui

Se a sua fórmula começar em uma linha diferente da primeira, a fórmula precisará ser alterada um pouco porque ela usa ROW()o que depende da linha em que a fórmula está colocada.

† Nota: Para usar a fórmula, você deve pressionar e segurar Ctrl+ Shifte pressionar Enterapós inseri-la.

informação relacionada