Excel: como pesquisar informações de células em várias pastas de trabalho

Question

Atualmente recebemos formulários eletrônicos preenchidos em Excel de nossos clientes, então tenho uma pasta cheia de apostilas.

Cada pasta de trabalho possui várias planilhas.

Preciso pesquisar cada uma das pastas de trabalho para ver se o intervalo "J8:Y8 na Planilha3" e "G8:AC8 na Planilha 4" foi preenchido, pois precisam de um exame mais minucioso, mas apenas algumas terão essas planilhas preenchidas.

Além disso, cada pasta de trabalho recebeu um nome completamente diferente.

Encontrei este código (abaixo) online que, em princípio, faz o que preciso. No entanto, ele pesquisa em cada planilha da pasta de trabalho um “Valor” específico.

Sub SearchFolders()
Dim fso As Object
Dim fld As Object
Dim strSearch As String
Dim strPath As String
Dim strFile As String
Dim wOut As Worksheet
Dim wbk As Workbook
Dim wks As Worksheet
Dim lRow As Long
Dim rFound As Range
Dim strFirstAddress As String
      

On Error GoTo ErrHandler
Application.ScreenUpdating = False


'Change as desired
strPath = "c:\MyFolder"
strSearch = "Specific text"

Set wOut = Worksheets.Add
lRow = 1
With wOut
    .Cells(lRow, 1) = "Workbook"
    .Cells(lRow, 2) = "Worksheet"
    .Cells(lRow, 3) = "Cell"
    .Cells(lRow, 4) = "Text in Cell"
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set fld = fso.GetFolder(strPath)

    strFile = Dir(strPath & "\*.xls*")
    Do While strFile <> ""
        Set wbk = Workbooks.Open _
          (Filename:=strPath & "\" & strFile, _
          UpdateLinks:=0, _
          ReadOnly:=True, _
          AddToMRU:=False)

        For Each wks In wbk.Worksheets
            Set rFound = wks.UsedRange.Find(strSearch)
            If Not rFound Is Nothing Then
                strFirstAddress = rFound.Address
            End If
            Do
                If rFound Is Nothing Then
                     lRow = lRow + 1
                    .Cells(lRow, 1) = wbk.Name
                    .Cells(lRow, 2) = wks.Name
                    .Cells(lRow, 3) = rFound.Address
                    .Cells(lRow, 4) = rFound.Value
Else
Exit Do

                End If
                Set rFound = wks.Cells.FindNext(After:=rFound)
            Loop While strFirstAddress <> rFound.Address
        Next

            wbk.Close (False)
            strFile = Dir
        Loop
        .Columns("A:D").EntireColumn.AutoFit
    End With
    MsgBox "Done"

ExitHandler:
    Set wOut = Nothing
    Set wks = Nothing
    Set wbk = Nothing
    Set fld = Nothing
    Set fso = Nothing
    Application.ScreenUpdating = True
    Exit Sub

ErrHandler:
    MsgBox Err.Description, vbExclamation
    Resume ExitHandler
End Sub

Answer 1

Este código funcionará da seguinte maneira:

1. Abra uma nova pasta de trabalho onde quiser.
2. Cole o código VBA na macro

3. Na célula A1 da Planilha 1 coloque o caminho para a pasta das pastas de trabalho, por exemplo:C:\users\yourname\folder\

4. Na Célula A2 o primeiro intervalo, por exemplo: J8:Y8e na Célula B2 o nome da Planilha:Sheet3

5. Na Célula A3 o segundo intervalo, por exemplo: G8:AC8e na Célula B3 o nome da Planilha:Sheet4

O melhor desse código é que se você tiver mais intervalos/planilhas para pesquisar você pode adicionar nas próximas linhas.

Isso parecerá assim:

Agora execute a macro e após sua execução irá mostrar os resultados emPlanilha2, mostrando o nome do arquivo e o número de células vazias em cada intervalo.

Sub foldersearch()
    Dim wbk As Workbook
    Dim wbk1 As Workbook
    Dim wks As Worksheet
    Dim wks2 As Worksheet
    Dim totaltime As Long
    Dim dtDuration As Date
    Set wbk = ThisWorkbook
    Set wks = wbk.Sheets(1)
    Set wks2 = wbk.Sheets(2)
    starttime = Now()
    wks2.Cells.ClearContents
    dirPath = wks.Cells(1, 1)
    file = Dir(dirPath)
    rowscounter = 0
    Application.ScreenUpdating = False
    While (file <> "")
        If InStr(file, "xls") > 0 Then
            rowscounter = rowscounter + 1
            totalpath = dirPath & file
            Set wbk1 = Workbooks.Open(totalpath, , True)
            rangelist = True
            i = 2
            columnscounter = 2
            While rangelist = True
                thenewrango = wks.Cells(i, 1)
                thenewsheet = wks.Cells(i, 2)
                emptycount = workbooksearch(wbk1, thenewsheet, thenewrango)
                wks2.Cells(rowscounter, 1) = file
                wks2.Cells(rowscounter, columnscounter) = emptycount
                i = i + 1
                columnscounter = columnscounter + 1
                If wks.Cells(i, 1) = "" Then
                    rangelist = False
                End If
            Wend
            wbk1.Close (False)
        End If
        file = Dir
    Wend
    Application.ScreenUpdating = True
    endtime = Now()
    totaltime = DateDiff("s", starttime, endtime)
    a = MsgBox("Finished in" & vbCrLf & totaltime & " seconds", vbOKOnly)
End Sub
Function workbooksearch(wbk1 As Workbook, wksname As Variant, rango As Variant)
    Dim wks1 As Worksheet
    Dim obj As Object
    On Error GoTo HandleError
    Set obj = wbk1.Sheets(wksname)
    Set wks1 = wbk1.Worksheets(wksname)
    emptycount = 0
    For Each c In wks1.Range(rango)
        If c.Value = "" Then
            emptycount = emptycount + 1
        End If
    Next c
    workbooksearch = emptycount
    Exit Function
HandleError:
    workbooksearch = "N/A"
End Function