Analisar string usando script em lote

Question 1

Um dos principais problemas da sua lógica é que você define a variável "import" uma vez se algo for verdade, mas nunca a reinicia ou a indefinida se não for mais verdade. Assim, após a primeira vez que for definido, ele permanecerá "definido" pelo resto do loop.

Minha preferência é definir a variável especificamente ( trueou false). Configure-o para falseiniciar e, em seguida, configure-o truecomo desejado, mas também certifique-se de configurá-lo novamente para falsequando precisar. Então, a cada iteração do loop, verifique se a variável está especificamente definida Trueou Falseem vez de verificar se está apenas definida.

Este código funciona para mim com base em suas informações/objetivos:

@echo off

setlocal EnableDelayedExpansion

set buildlog=test.txt
set import=false

for /F "tokens=*" %%A in (%buildlog%) do (
    if /i "%%A"=="Import:" (
        set import=true
    )
    if /i "%%A"=="View:" (
        set import=false
    )
    if !import!==true (
        if not "%%A"=="Import:" (
            for /F "tokens=1" %%B in ("%%A") do (
                echo %%B
            )
        )
    )
)

Definimos propositalmente a variável (sinalizador) "Importar" como para falsecomeçar.

O primeiro loop For passa por cada linha do arquivo ( test.txtneste exemplo, conforme especificado pela variável "buildlog"; nota: você precisa remover as aspas ao redor do nome do arquivo na variável para que ele funcione no loop For) .

O primeiro IF verifica se a linha atual é a linha "Import:" e, em caso afirmativo, inverte o sinalizador "import" para true.

O próximo IF verifica se a linha atual é a linha "View:" e, em caso afirmativo, inverte o sinalizador "import" (de volta para) para false, para interromper o processamento de cada linha.

O terceiro IF verifica se o sinalizador "import" é truee, em caso afirmativo, processa a linha.

Se for, trueo (4º) IF aninhado verifica se a linha é a linha "import:" real e, se não, exibe a linha (evita que ela mostre a linha "Import:" na saída).

O segundo loop For passa pela linha que queremos exibir e puxa apenas o primeiro conjunto de tokens que é (apenas) o caminho que você deseja, deixando de fora o #head.

Mais/informações relacionadas:

Editar após comentários:

Para lidar com a linha "View:" se ela tiver um número de versão depois dela, você pode modificar o código para algo como:

@echo off

setlocal EnableDelayedExpansion

set buildlog=test.txt
set import=false

for /F "tokens=*" %%A in (%buildlog%) do (
    for /F "tokens=1" %%B in ("%%A") do (
        if /i "%%B"=="Import:" (
            set import=true
        )
        if /i "%%B"=="View:" (
            set import=false
        )
        if !import!==true (
            if not "%%B"=="Import:" (
                for /F "tokens=1" %%C in ("%%A") do (
                    echo %%C
                )
            )
        )
    )
)

Este loop For adicionado puxará o primeiro token da linha para verificar se é "Visualizar:" ou "Importar:" em vez de verificar a linha inteira. Ignorando efetivamente qualquer coisa após o primeiro espaço encontrado na linha para fazer a verificação.

Answer