Como preencher uma célula com valores de outra planilha, mas aumentar o endereço da célula em 3?

Question

Eu sei como preencher uma célula com valores de outra planilha. Mas como pulo para a terceira célula?

Aqui está o que estou tentando fazer:

A1 ='2nd Worksheet'!C4
A2 ='2nd Worksheet'!C7
A3 ='2nd Worksheet'!C10
A4 ='2nd Worksheet'!C13
A5 ='2nd Worksheet'!C16
A6 ='2nd Worksheet'!C19
A7 ='2nd Worksheet'!C22
and so on... 

sem ter que digitar manualmente '2nd Worksheet'!Cxxincrementando 3 de cada vez.

Answer 1

Insira a seguinte fórmula na célula A1 e arraste para baixo:

=OFFSET(Folha2!$C$4,3*LINHA()-3,0)

Answer 2

Aqui estão algumas variações:

• A1→ =OFFSET('2nd Worksheet'!C$1, 3*ROW(), 0)
  Isso faz referência à C1célula 2nd Worksheet e depois desce três linhas × o número da linha atual. Então, quando você arrastar/preencher isso, você obterá

  • A1→ =OFFSET('2nd Worksheet'!C$1, 3, 0)→'2nd Worksheet'!C4
  • A2→ =OFFSET('2nd Worksheet'!C$1, 6, 0)→'2nd Worksheet'!C7
  • A3→ =OFFSET('2nd Worksheet'!C$1, 9, 0)→'2nd Worksheet'!C10

  Você precisa especificar $in C$1para torná-lo uma referência de linha absoluta; caso contrário, quando você arrastar/preencher, você obterá

  • A1→ =OFFSET('2nd Worksheet'!C1, 3, 0)→'2nd Worksheet'!C4
  • A2→ =OFFSET('2nd Worksheet'!C2, 6, 0)→'2nd Worksheet'!C8
  • A3→ =OFFSET('2nd Worksheet'!C3, 9, 0)→'2nd Worksheet'!C12

  (porque o número da linha é incrementado automaticamente). Você pode dizer $C$1se quiser; isso não fará diferença (a menos que você comece a mover ou copiar entre colunas).

• A1→ =INDIRECT("'2nd Worksheet'!C" & 3*ROW()+1)
  Isso simplesmente constrói as strings que você mostrou em sua pergunta e, em seguida, usa a INDIRECT()função para desreferenciar essas strings (ou seja, para tratá-las como endereços de células e recuperar o conteúdo das células identificadas).