Mova os últimos N arquivos da pasta no Windows 8.1

Question

Eu queria saber - existe uma maneira agradável e elegante no Windows 8.1 de mover os últimos N arquivos de uma pasta para outra pasta que não seja escrever um programa para fazer isso?

Editar: N é, por exemplo, 100 e os arquivos são classificados por nome.

Answer 1

Como movo os últimos N arquivos de uma pasta?

N é, por exemplo, 100 e os arquivos são classificados por nome.

Use o seguinte arquivo em lote (test.cmd):

@echo off
rem parameters
rem %1 number of files to move
rem %2 source directory
rem %3 target directory
Setlocal EnableDelayedExpansion
rem initialise number of files
set count=0
rem count files
for /f "delims=" %%a in ('dir %2 /a-d /b /O:N') do @(set /a count+=1 >nul)
rem set number of files to skip (not move)
set /a "skip=count-%1"
rem move the files
for /f "skip=%skip% delims=" %%a in ('dir %2 /a-d /b /O:N') do echo move %2\%%a %3\%%a

Remova o echode do echo move...quando estiver satisfeito com o fato de o arquivo em lote estar funcionando de acordo com sua satisfação.

Uso:

test N Source Target

Onde:

• Nnúmero de arquivos para mover
• Sourcediretório de origem
• Targetdiretório de destino

Exemplo:

C:\test>dir
 Volume in drive C has no label.
 Volume Serial Number is C8D0-DF1E

 Directory of C:\test

31/05/2015  11:31    <DIR>          .
31/05/2015  11:31    <DIR>          ..
26/05/2015  18:20               117 address.out
26/05/2015  18:16               265 data.txt
31/05/2015  11:25    <JUNCTION>     junction [f:\test]
31/05/2015  11:31    <DIR>          sub
31/05/2015  18:16               449 test.cmd
               3 File(s)            831 bytes
               4 Dir(s)  95,480,258,560 bytes free

C:\test>test 1 . c:\temp
move .\test.cmd c:\temp\test.cmd
C:\test>

---

Leitura adicional

• Um índice AZ da linha de comando do Windows CMD- Uma excelente referência para todas as coisas relacionadas à linha cmd do Windows.