☰

Várias fórmulas em uma célula com condição IF

tag-icon • tag-icon microsoft-excel
Várias fórmulas em uma célula com condição IF

Estou tentando descobrir como posso inserir várias fórmulas em uma única célula. O cálculo refere-se à data e hora.

Abaixo estão minhas perguntas.

Se A1 = Data e B1 = Hora (militar)EC1=Data e D1=Hora (militar), para obter a diferença de tempo, em horas, estou utilizando a fórmula abaixo, em F1.

=((C1+D1)-(A1+B1))*24

O que preciso fazer é para F1 determinar se não há valor em A1 e B1 do que usar a =now()função para completar a fórmula. Em outras palavras, preciso da seguinte fórmula para funcionar.

=(now()-(A1+B1))*24

ou algo desse tipo.

Sou iniciante no Excel e preciso disso para criar um relatório de medição de tempo.

Responder1

A primeira pergunta é: exatamente qual condição você deseja testar? Eu acho que você quer

OR(ISBLANK(C1), ISBLANK(D1))

ou

OR(C1="", D1="")

o que significa quase a mesma coisa - C1ou D1está em branco. Outras possibilidades incluem

  • AND(ISBLANK(C1), ISBLANK(D1))

    ou

    AND(C1="", D1="")

  • ISBLANK(C1)

    ou

    C1=""

    com a expectativa de que um espaço em branco D1seja tratado como 00:00.

  • (C1+D1)=0

    o que é praticamente equivalente a AND(C1="", D1="").

Depois de escolher sua condição, a IFfunção é bastante fácil. A solução da “força bruta” seria

=IF(OR(C1="",D1=""), (NOW()-(A1+B1))*24, ((C1+D1)-(A1+B1))*24)

Mas você pode mover as partes comuns para fora:

=(IF(OR(C1="",D1=""), NOW(), C1+D1) - (A1+B1)) *24

Responder2

O Excel já é perfeitamente capaz de armazenar datas e horas exatamente como você precisa - você não precisa multiplicar as coisas por 24, etc. Se você apenas usar formatcélulas como Datas ou Horas, elas serão exibidas como horas e minutos automaticamente ( 1,0 = 24h, 0,5 = 12h etc.)

Mas acho que a fórmula que você procura deveria ser:

=IF((A1+B1)>0,now()-A1+B1,0)

Esta fórmula testa se o total de A1 e B1 é maior que zero e depois retorna sua fórmula. Caso contrário, ele retorna zero. Se você formatou a célula para mostrar a hora, esse zero poderá aparecer como 00:00, que parece ser o que você está pedindo.

informação relacionada