☰

Extraia rar multipart, excluindo partes à medida que são extraídas

tag-icon • tag-icon windows compression rar
Extraia rar multipart, excluindo partes à medida que são extraídas

Eu tenho um rar multiparte de 80 GB descompactado. Tenho 5 GB de espaço livre e cada parte do arquivo rar tem 2 GB.

O que procuro é extrair uma parte, deletar, extrair a próxima e assim por diante, para usar no máximo mais 5 GB no processo de extração e não esgotar todo o espaço em disco.

Responder1

IMPORTANTE:

  • este roteiroVAIexclua as partes extraídas independentemente do resultado final, portanto, se o processo parar por uma parte ausente ou corrompida, você não poderá recomeçar
  • Abra o bloco de notas e cole o seguinte código e salve-o como_unrar.vbsna mesma pasta com seus arquivos rar.
  • DefinirDesRAR_Full_Path,Primeira parteePasta_alvo, certifique-se de manter as aspas.

O roteiro:

UnRAR_Full_Path = "c:\program files\winrar\unrar.exe"
First_Part = "YourArchiveName.part001.rar"
Target_Folder = "ExtractedFiles\"

mf_command = AddQuotes(UnRAR_Full_Path) & " x " & AddQuotes(First_Part) & " " & AddQuotes(Target_Folder)
mf_LZerosSplit = Split(First_Part, ".")
mf_LZerosPart = Mid(mf_LZerosSplit(UBound(mf_LZerosSplit)-1), 5)
If UBound(mf_LZerosSplit) > 3 Then
    WScript.Echo ("Too Lazy to deal with names the contains dots, only 2 are allowed. one before 'part' and one before 'rar'")
    WScript.Quit 1
End If
mf_LZ_UnderTen = ""
mf_LZ_UnderHundred = ""
mf_LZ_UnderThousand = ""

If Len(mf_LZerosPart) = 2 Then
    mf_LZ_UnderTen = "0"

ElseIf Len(mf_LZerosPart) = 3 Then
    mf_LZ_UnderTen = "00"
    mf_LZ_UnderHundred = "0"

ElseIf Len(mf_LZerosPart) = 4 Then
    mf_LZ_UnderTen = "000"
    mf_LZ_UnderHundred = "00"
    mf_LZ_UnderThousand = "0"
End If 
Set objShell = CreateObject("WScript.Shell")
Set objWshScriptExec = objShell.Exec(mf_command)
Set objStdOut = objWshScriptExec.StdOut

While Not objStdOut.AtEndOfStream
    strLine = objStdOut.ReadLine

    'WScript.Echo (strLine)

        If InStr(strLine,"Extracting from") Then
            mf_filename = Mid(strLine, 17)
            mf_partnameSplit = Split(mf_filename, ".")
            mf_partname = mf_partnameSplit(1)
            mf_partnumber = Mid(mf_partname , 5)
            If mf_partnumber > 1 Then
                mf_numtodel = mf_partnumber-1
                mf_LeadingZeros = ""
                If mf_numtodel < 10 Then
                    mf_LeadingZeros = mf_LZ_UnderTen
                ElseIf mf_numtodel < 100  Then
                    mf_LeadingZeros = mf_LZ_UnderHundred
                ElseIf mf_numtodel < 1000  Then
                    mf_LeadingZeros = mf_LZ_UnderThousand
                End If
                mf_filetodel = mf_partnameSplit(0) & ".part" & mf_LeadingZeros & mf_numtodel & ".rar"

                'WScript.Echo ("NOW DELETING: " & mf_filetodel)

                Set obj = CreateObject("Scripting.FileSystemObject")
                obj.DeleteFile(mf_filetodel)
            End If
        ElseIf InStr(strLine,"All OK") Then
            WScript.Echo ("looks like All Ok, Delete the Last part and Have a nice day :)")
        End If
Wend

Function AddQuotes(strInput)
    AddQuotes = Chr(34) & strInput & Chr(34)
End Function

Opção um:Silencioso

execute o_unrar.vbsarquivo clicando duas vezes nele

Opção dois:Recomendado

remova o'desde o início

'WScript.Echo (strLine)

'WScript.Echo ("Deleting: " & mf_filetodel)

abra o cmd, vá direto para sua pasta e digite"cscript _unrar.vbs"

  • usandoWScript.Echosemscriptirá aparecer muitas caixas de mensagens irritantes

este script funciona lendo o Stdout do UnRAR.exe.

EDITAR

Melhorado o script para funcionar automaticamente com qualquer estrutura de nome e com qualquer número de peças até 9.999 peças. e trabalhar com arquivos legados que não contenham zeros à esquerda.

informação relacionada