☰

Como aplicar uma fórmula macro/vba a mais de uma célula

tag-icon • tag-icon vba macros
Como aplicar uma fórmula macro/vba a mais de uma célula

Eu inseri o seguinte:

Private Sub Worksheet_Change(ByVal Target As Range)

If Target.Address = "$V$2" Then
    Range("U2") = Range("V2") * Range("O2")
End If

If Target.Address = "$U$2" Then
    Range("V2") = Range("U2") / Range("O2")
End If

End Sub

.....No entanto, isso só funciona nas células u2 e v2. Preciso que esta fórmula seja executada até a coluna U e a coluna V.

Qualquer ajuda é apreciada.

Responder1

Se bem entendi, você poderia usar algo assim.

Private Sub Worksheet_Change(ByVal Target As Range)

    'Don't apply to column headers
    If Target.Row = 1 Then Exit Sub

    'Make changes to anything in Column V (22)
    If Target.Column = 22 Then
        If IsNumeric(Range("V" & Target.Row)) And IsNumeric(Range("O" & Target.Row)) Then
            Range("U" & Target.Row) = Range("V" & Target.Row) * Range("O" & Target.Row)
        End If
    End If

    'Make changes to anything in Column U (21)
    If Target.Column = 21 Then
        If IsNumeric(Range("U" & Target.Row)) And IsNumeric(Range("O" & Target.Row)) And Range("O" & Target.Row) <> 0 Then
            Range("V" & Target.Row) = Range("U" & Target.Row) / Range("O" & Target.Row)
        End If
    End If

End Sub

Este evento é acionado sempre que uma célula é alterada. Como tal, ele irá verificar em qual coluna está a alteração - If Target.Column = 22 Then... Se a coluna for 22 (Representação numérica para coluna V) ele irá progredir para o restante do código, que é alterar U, V e O usando o Target.Row, que é o número da linha da célula alterada.

Editar: Adicionada a verificação Dividir por Zero e verificar se todos os itens inseridos são de fato números e não letras/símbolos.

Responder2

Considerar:

Private Sub Worksheet_Change(ByVal Target As Range)
   If Target.Row = 1 Then Exit Sub
   If Intersect(Target, Range("U:V")) Is Nothing Then Exit Sub
   Application.EnableEvents = False
      If Not Intersect(Target, Range("V:V")) Is Nothing Then
         Target.Offset(0, -1).Value = Target.Value / Range("O" & Target.Row).Value
      Else
         Target.Offset(0, 1).Value = Target.Value / Range("O" & Target.Row).Value
      End If
   Application.EnableEvents = True
End Sub

Observação: Isso exclui a primeira linha.

informação relacionada