☰

parada de diferença após a primeira diferença

tag-icon • tag-icon linux diff comparison
parada de diferença após a primeira diferença

Eu gostaria de executar um diffem 2 arquivos e parar na primeira diferença. Não exijo que o comando seja executado via diff, é claro, mas exijo que o comando real cesse assim que a primeira diferença for encontrada e relatada. Estou correndo em algunsmuitoarquivos grandes e espera uma combinação perfeita, mas ainda quer saber qual era a diferença, caso alguma fosse encontrada, então diff -q, diff ... |head -1, e cmpnão são bons. E, como os arquivos são muito grandes, seria bom algo que não esgotasse a memória. Embora não seja necessário para o meu problema atual, pontos extras para soluções que funcionam para as primeiras n diferenças (especificadas pelo usuário) e para aquelas que podem ignorar diferenças de espaços em branco.

Responder1

cmppára na primeira diferença:

% cat foo
foo
bar
baz
---
foo
bar
baz
% cat bar
foo
bar
baz
---
foo+
bar+
baz+
% cmp foo bar
foo bar differ: byte 20, line 5
%

Você poderia envolver um script para imprimir as diferentes linhas:

#! /bin/bash
line=$(cmp "$1" "$2" | awk '{print $NF}')
if [ ! -z $line ]; then
    awk -v file="$1" -v line=$line 'NR==line{print "In file "file": "$0; exit}' "$1"
    awk -v file="$2" -v line=$line 'NR==line{print "In file "file": "$0; exit}' "$2"
 fi

% ./script.sh foo bar
In file foo: foo
In file bar: foo+

Parte do custo agora é transferido para os comandos AWK, mas deve ser significativamente mais rápido do que verificar ambos os arquivos inteiramente.

Responder2

Testei isso com casos triviais, mas deixo o teste de campo para você:

$ cat f1
l1
l21 l22       l23  l24


l3
l4x
l5


$ cat f2
l1
l21 l22       l23

l3
l4y
l5



$ cat awkdiff.awk


BEGIN {
   maxdiff = 5
   ignoreemptylines = 1
   whitespaceaware = 1

   if (whitespaceaware) {
      emptypattern = "^[[:space:]]*$"
   } else {
      emptypattern = "^$"
      FS=""
   }

   f1 = ARGV[1]
   f2 = ARGV[2]

   rc1=rc2=1
   while( (rc1>0 && rc2>0 && diff<maxdiff)  ) {
      rc1 = getline l1 < f1 ; ++nr1
      rc2 = getline l2 < f2 ; ++nr2

      if (ignoreemptylines) {
         while ( l1 ~ emptypattern   &&  rc1>0) {
            rc1 = getline l1 < f1 ; ++nr1
         }

         while ( l2 ~ emptypattern  &&  rc2>0) {
            rc2 = getline l2 < f2 ; ++nr2
         }
      }


      if ( rc1>0 && rc2>0) {
         nf1 = split( l1, a1)
         nf2 = split( l2, a2)

         if ( nf1 <= nf2) {
            nfmin = nf1
         } else {
            nfmin = nf2
         }

         founddiff = 0
         for (i=1; i<=nfmin; ++i) {
            if ( a2[i]"" != a1[i]"") {
               printf "%d:%d:{%s} != %d:%d:{%s}\n", \
                  nr1, nf1, a1[i], nr2, nf2, a2[i]
               founddiff=1
               ++diff
               break
            }
         }

         if ( !founddiff  &&  nf1 != nf2) {
            if ( nf1 > nf2)
               printf "%d:%d:{%s} != %d:EOL\n", nr1, nfmin+1, a1[nfmin+1], nr2
            else
               printf "%d:EOL != %d:%d:{%s}\n", nr1, nr2, nfmin+1, a2[nfmin+1]
            ++diff
         }
      } else {
         if ( rc1 == -1 && rc2 == -1) {
            print "IO error"
         } else if ( rc1 == 1 && rc2 == 0) {
            print "%d:%s != EOL\n", nr1, l1
         } else if ( rc1 == 0 && rc2 == 1) {
            printf "EOL != %d:%s\n", nr2, l2
         }
      }
   }
}


$ awk -f awkdiff.awk  /tmp/f1 /tmp/f2
2:4:{l24} != 2:EOL
6:1:{l4x} != 5:1:{l4y}

maxdiff = N: define o número máximo de diferenças nas quais a comparação deve parar

ignoreemptylines = 1|0: especifica se linhas vazias devem ser ignoradas ao comparar

whitespaceaware = 1|0: especifica se a comparação deve ser feita wordwise (assumindo espaços em branco consecutivos iguais) ou linewise

informação relacionada