Eu tenho uma pasta de trabalho principal do Excel na qual os usuários trabalham. A função desta pasta de trabalho do Excel é copiar e criar outra pasta de trabalho usando macros, etc. Esta cópia está localizada em uma unidade de rede onde todos podem acessá-la. O problema é que, se alguém copiou esta versão para sua área de trabalho e mais tarde eu criar uma nova versão desta pasta de trabalho principal, a antiga que a pessoa copiou para sua área de trabalho não terá as atualizações mais recentes para as macros e etc. . Existe uma maneira de verificar ou impedir que o antigo consiga executar as macros ou que a pasta de trabalho antiga funcione?
Responder1
Passo 1:Você pode escrever uma macro que irá verificar o arquivo principal em um local de rede. Você pode usar Dir
ou FSO
para fazer isso:
Dir:
Sub Test_File_Exist_With_Dir()
Dim FilePath As String
Dim TestStr As String
FilePath = "\\Server\test\book1.xlsm"
TestStr = ""
On Error Resume Next
TestStr = Dir(FilePath)
On Error GoTo 0
If TestStr = "" Then
MsgBox "File doesn't exist"
Else
MsgBox "File exist"
End If
End Sub
FOE:
Sub Test_File_Exist_FSO_Late_binding()
'No need to set a reference if you use Late binding
Dim FSO As Object
Dim FilePath As String
Set FSO = CreateObject("scripting.filesystemobject")
FilePath = "\\Server\test\book1.xlsm"
If FSO.FileExists(FilePath) = False Then
MsgBox "file doesn't exist"
Else
MsgBox "File exist"
End If
End Sub
Sub Test_File_Exist_FSO_Early_binding()
'If you want to use the Intellisense help showing you the properties
'and methods of the objects as you type you can use Early binding.
'Add a reference to "Microsoft Scripting Runtime" in the VBA editor
'(Tools>References)if you want that.
Dim FSO As Scripting.FileSystemObject
Dim FilePath As String
Set FSO = New Scripting.FileSystemObject
FilePath = "\\Server\Ron\test\book1.xlsm"
If FSO.FileExists(FilePath) = False Then
MsgBox "File doesn't exist"
Else
MsgBox "File exist"
End If
End Sub
Passo 2:Você pode fazer com que ele verifique a data da última modificação desse arquivo, que pode ser usada para determinar se existe uma versão mais recente.
FileDateTime("\\Server\test\book1.xlsm")
Resultado da amostra:01/06/2016 19:40:18
Etapa 3:Se existir uma versão mais recente, você poderá exibir uma caixa de mensagem para o usuário copiar a nova versão da unidade de rede e fechar a pasta de trabalho. (Eu não recomendaria a automação para copiar/colar do local da rede para a estação de trabalho do usuário, pois isso poderia facilmente ficar confuso e, sem isso, ainda faria o que era necessário)
MsgBox "A new version of this file exists on the network share. Please use the new version. This workbook will now close."
ActiveWorkbook.Close savechanges:=False
Referências: