☰

XML mal formatado com script em lote

tag-icon • tag-icon windows-7 command-line batch 64-bit xml
XML mal formatado com script em lote

Eu tenho um script em lote como abaixo para criar um arquivo XML com estrutura específica e organização de tags.

@ECHO OFF
SET ROOTPATH=%~dp0
SET LINEBREAK=^^%NLM%%NLM%^%NLM%%NLM%
SET "TAB=   "
SET /p COMPANY="Company Name: "
SET /p MODULE="Module Name: "
SET /p CODEPOOL="Code Pool: "
ECHO ^<?xml version="1.0"?^>"%LINEBREAK%"^<config^>"%LINEBREAK%""%TAB%"^<modules^>"%LINEBREAK%""%TAB%""%TAB%"^<"%COMPANY%_%MODULE%"^>"%LINEBREAK%""%TAB%""%TAB%""%TAB%"^<active^>true^</active^>"%LINEBREAK%""%TAB%""%TAB%""%TAB%"^<codePool^>local^</codePool^>"%LINEBREAK%""%TAB%""%TAB%"^</"%COMPANY%_%MODULE%"^>"%LINEBREAK%""%TAB%"^</modules^>"%LINEBREAK%"^</config^>>"%ROOTPATH%app\etc\modules\%COMPANY%_%MODULE%.xml"
PAUSE

Agora pretendo criar um arquivo XML como o código XML de exemplo abaixo, com uma quantidade específica de novas linhas e caracteres de tabulação sempre que necessário para recuo, também sei como imprimir a nova linha e tabulações em arquivos em lote também como você viu no script fornecido acima :

<?xml version="1.0"?>
<config>
    <modules>
        <Company_Module>
            <active>true</active>
            <codePool>community</codePool>
        </Company_Module>
    </modules>
</config>

Mas quando eu crio o arquivo XML, ele sempre fica mal formatado como abaixo:

<?xml version="1.0"?>"^SET "TAB=    ""<config>"^SET "TAB=   """"<modules>"^SET "TAB=    """"""<"Company_Module">"^SET "TAB= """"""""<active>true</active>"^SET "TAB=    """"""""<codePool>local</codePool>"^SET "TAB=   """"""</"Company_Module">"^SET "TAB=    """"</modules>"^SET "TAB=   ""</config>

Alguém pode me dizer por que isso acontece e como resolvê-lo apenas por código de lote e padrões?

Responder1

Não importa, eu descobri a solução sozinho pesquisando no Google truques de impressão de caracteres de script em lote.

Eu resolvi isso usando ENABLEDELAYEDEXPANSIONo script em lote.

Espero que alguém com o mesmo problema considere o script abaixo útil:

@ECHO OFF
SET ROOTPATH=%~dp0
SET \t= 
SET /p COMPANY="Company Name: "
SET /p MODULE="Module Name: "
SET /p CODEPOOL="Code Pool: "
(SET \n=^
%=DONT REMOVE THIS=%
)
SETLOCAL ENABLEDELAYEDEXPANSION
ECHO ^<?xml version="1.0"?^>!\n!^<config^>!\n!%\t%^<modules^>!\n!%\t%%\t%^<%COMPANY%_%MODULE%^>!\n!%\t%%\t%%\t%^<active^>true^</active^>!\n!%\t%%\t%%\t%^<codePool^>local^</codePool^>!\n!%\t%%\t%^</%COMPANY%_%MODULE%^>!\n!%\t%^</modules^>!\n!^</config^>>%ROOTPATH%app\etc\modules\%COMPANY%_%MODULE%.xml
ENDLOCAL

Após usar o script acima com argumentos: "Empresa1", "Módulo1", "local"; nessa ordem, gerei o documento XML abaixo:

<?xml version="1.0"?>
<config>
    <modules>
        <Company1_Module1>
            <active>true</active>
            <codePool>local</codePool>
        </Company1_Module1>
    </modules>
</config>

Obrigado de qualquer maneira. Se alguém tiver uma abordagem melhor e mais curta, fique à vontade para postar aqui.

Responder2

Tem que ser em uma única linha? Usando o cmd, você pode rapidamente atingir a limitação do comprimento da linha dessa maneira. Se usar várias linhas for uma opção:

@ECHO OFF
SET ROOTPATH=%~dp0
SET \t=   
SET /p COMPANY="Company Name: "
SET /p MODULE="Module Name: "
SET /p CODEPOOL="Code Pool: "

(
echo.^<?xml version="1.0"?^>
echo.^<config^>
echo.%\t%^<modules^>
echo.%\t%%\t%^<%COMPANY%_%MODULE%^>
echo.%\t%%\t%%\t%^<active^>true^</active^>
echo.%\t%%\t%%\t%^<codePool^>%CODEPOOL%^</codePool^>
echo.%\t%%\t%^</%COMPANY%_%MODULE%^>
echo.%\t%^</modules^>
echo.^</config^>
)>>%ROOTPATH%app\etc\modules\%COMPANY%_%MODULE%.xml

Se você insiste em usar uma única linha, a expansão atrasada em combinação com o caractere de nova linha já é o método mais simples. Se você quiser evitar a expansão atrasada, também existem outras maneiras de expressar a variável, conforme explicado emeste tópico.

informação relacionada