☰

Microsoft Excel, múltiplas fórmulas em uma célula

tag-icon • tag-icon microsoft-excel
Microsoft Excel, múltiplas fórmulas em uma célula

Gostaria de ajuda para colocar várias fórmulas em uma célula.

se eu inserir 1 em g11, gostaria que usasse a fórmula abaixo =if(H11="","",I11/(230*H11))

se eu inserir 3 em g11, gostaria de usar a fórmula abaixo =if(H11="","",I11/(sqrt(3)*400*H11*(E11/100)))

desde já, obrigado

Responder1

Você também pode usar a mesma função IF para testar a célula G11: (use esta fórmula em uma única linha)

=if(G11=1,  
    if(H11="","",I11/(230*H11)), 
    if(G11=3, 
            if(H11="","",I11/(sqrt(3)*400*H11*(E11/100))),
            ""
      )
   )

=if(G11=1,para testar se seu valor é 1
        if(H11="","",I11/(230*H11)),Condição verdadeira execute sua fórmula para 1
        if(G11=3,Se for Falso, teste seu valor para 3
              if(H11="","",I11/(sqrt(3)*400*H11*(E11/100))),se G11 for 3 então execute sua segunda fórmula
              ""se G11 outra coisa não faça nada
      )feche if(G11=3,,)
)feche se (G11=1,,)

Responder2

Que tal

 =IF(G11=1,IF(H11="","",I11/(230*H11)),IF( G11=3,IF(H11="","",I11/(SQRT(3)*400*H11*(E11/100))),""))

Responder3

Certamente você notou que suas duas fórmulas (opcionais) sãomuitosemelhante:

=if(H11="","",I11/(230        *H11          ))
 ↕↕↕↕↕↕↕↕↕↕↕↕↕↕↕↕↕↕           ↕↕↕↕          ↕↕
=if(H11="","",I11/(sqrt(3)*400*H11*(E11/100)))

e você pode reorganizar a segunda fórmula para simplificá-la e aumentar a similaridade:

 400*H11*(E11/100)
=400*(E11/100)*H11
=(400*E11/100)*H11
=(E11*400/100)*H11
=E11*(400/100)*H11
=E11 *   4   * H11
=4*E11*H11

Portanto, sua segunda fórmula se reduz a

=if(H11="","",I11/(sqrt(3)*4*E11*H11))

Podemos aproveitar essa semelhança para simplificar a fórmula geral (que foi dada em algumas outras respostas) para

=if(H11="","",I11/(IF(G11=1,230,IF(G11=3,sqrt(3)*4*E11,0))*H11))

Observe que, se G11for diferente de 1 ou 3, isso faz explicitamente uma divisão por 0, o que causará um erro. Não use esta resposta se isso for um problema para você.

informação relacionada