Uma tecla de atalho para mover um arquivo através de diretórios (MacOS)

Question

Existem teclas de atalho para mover pastas para cima ou para baixo nas pastas e subpastas principais no MacOS?

por exemplo, neste exemplo simples, quero mover o arquivo 1234.pdf para a pasta A, o que deixaria a subpasta A vazia. Idealmente, poderei fazer isso usando apenas o teclado. Pontos extras: uma tecla de atalho para selecionar novamente a última subpasta selecionada (para que eu possa excluir, renomear, etc.).

- Folder A
   - Subfolder A
      -File 1234.pdf 
- Folder B

Answer 1

Peço desculpas pela demora em retornar com minha resposta. Tem sido mais desafiador do que eu esperava.

Mas é possível conseguir o que você deseja criando umserviçoemAutomatizador, que ficará acessível por meio de um atalho de teclado (tecla de atalho).

Você precisará seguireste guia sobre como fazer um serviço em todo o sistema.

---

Comece criando um novo serviço emAutomatizador. Será necessário receberarquivos ou pastascomo entrada e ser disponibilizado emLocalizador.

Adicione umExecute o AppleScriptação para o fluxo de trabalho. Na área de texto dessa ação, o seguinte AppleScript pode ser copiado e colado:

    use Finder : application "Finder"

    property F_ : missing value -- The previous folder
    property f : missing value -- The files that we moved
    property home : Finder's home as alias


    on run {f, _}
      get its ParentFolderOf:(some item in f)
      set there to the result -- The destination folder, one level up

      -- We won't navigate any higher up the folder tree than
      -- the home folder
      if (its ParentFolderOf:home) is in there then return

      -- Also don't apply this service to other folders that aren't
      -- in the same branch of the folder tree as the home folder
      if (there as text) does not begin with (home as text) then return

      -- The folder we're currently at
      tell Finder to set F_ to ¬
        (the container of some item in f) as alias

      -- Check to ensure there are no files in the destination folder
      -- that risk being overwritten.  If there are, we won't move
      -- the files who share the same name, i.e. only move those that 
      -- are safe to move.
      tell Finder to ¬
        repeat with _g in f
          get name of _g
          set g to [there as text, result] as text
          if not (g exists) then set end of f to _g
          set f to the rest of f
        end repeat

      -- Move the files
      tell Finder ¬
        to set f ¬
        to (move f to there) ¬
        as list as alias list

      -- Reveal them
      reveal f
      activate Finder
    end run


    to ParentFolderOf:(f as alias)
      local f

      set F_ to [f, "::"] as text as alias

      if (f as text) ends with ":" then return F_

      return its ParentFolderOf:F_
    end ParentFolderOf:

Salve o serviço como quiser. Automatizadorsalva automaticamente no local certo (~/Biblioteca/Serviços). Eu salvei o meu como"Ascender no Finder".

Em seguida, você deve criar um atalho de teclado. Isto é feito atravésPreferências do Sistema:

Na lista de serviços, você precisará rolar para baixo até a seção marcadaArquivos e pastas, sob o qual o nome do seu serviço deve aparecer. Você pode ver o meu destacado. Eu criei o atalho ⌃▲para o meu (Ctrl+Cima).

Agora, toda vez que seleciono arquivos e/ou pastas noLocalizadore pressione ⌃▲, esses arquivos e pastas sobem um nível acima na hierarquia até sua pasta pai. Se eu quiser movê-los de volta, posso pressionar ⌘Zpara desfazer o movimento.

Coloquei uma proteção para que arquivos e pastas não fossem movidos para um nível mais alto na árvore de pastas do que sua pasta pessoal. É improvável que você precise de qualquer maneira.

Answer 2

Se você trabalha na visualização Coluna, poderá navegar apenas com as teclas de seta.

Por exemplo, supondo que você comece com o arquivo selecionado ...

• Cmd ⌘ C copiar

• Seta para a esquerda [isso selecionará a subpasta A], portanto, para ganhar pontos extras...

  • Enter ⌅ permitirá que você o renomeie ou Cmd ⌘ Backspace ⌫ exclua
    [Isso não perderá seu arquivo atualmente no buffer de cópia]

• Seta para a esquerda [isso selecionará a pasta A]*

• Cmd ⌘ Opt ⌥ V mover

Esta é a estrutura tal como aparece no início.

e novamente no final [depois de excluir a subpasta A no caminho]

*Como não é mencionado em nenhum lugar da resposta, neste ponto a seta para baixo selecionaria a pasta B