☰

Excel 2016/ Ajuda para criar uma função para adicionar número (48,20) como horas.minutos a uma data (04/03/2018 08:00)

tag-icon • tag-icon microsoft-excel microsoft-excel-2016
Excel 2016/ Ajuda para criar uma função para adicionar número (48,20) como horas.minutos a uma data (04/03/2018 08:00)

Eu aumentaria a data (04/03/2018 08:00) por determinado número.

Ex.

Célula A1 (04/03/2018 08:00)

Célula A2 (48.20) ///Número em horas e minutos que neste caso são 2 dias e 20 minutos

célula A3 (somando os números A2 na Data A1) = (06/03/2018 08:20)

Responder1

Supondo

  • O conteúdo A2 é um número decimal que representa horas e minutos e está no formato 00,00 (de modo que 48 horas e 2 minutos seriam 48,02), então:
=A1+TEXT(A2*100,"00\:00")

Se você preferir fórmulas mais obscuras, tente:

=A1+DOLLARDE(A2,60)/24

Responder2

A principal dificuldade nesta questão é que o valor a ser adicionado é registrado como o número decimal48,20, mas deve ser interpretado como48 horas e 20 minutos. Este é provavelmente um requisito. Esta resposta pressupõe que os minutos são codificados como números de dois dígitos, portanto, 2 minutos seriam 0,02 em vez de 0,2.

Esta solução converte o número decimal em dias e minutos e depois adiciona esses números à data. A parte inteira do número representa as horas, que podem ser convertidas em dias inteiros com qualquer uma destas fórmulas em C2:

C2=INT(B2/24)ou

C2=INT(CONVERT(B2,"hr", "day"))

Observe que isso funciona apenas para casos em que as horas são múltiplos de dias inteiros. Não produzirá uma resposta correta se as horas não forem dias inteiros. Além disso, a segunda fórmula não funcionará se as entradas forem realmente armazenadas como texto.

A seguir, a porção fracionária é convertida em minutos na célula D2:

=100*(B2-TRUNC(B2))ou

=(B2-INT(B2))*100ou

=MOD(B2,1)*100

Por último, estes resultados intermédios são adicionados à data utilizando esta fórmula final em E2:

=DATE(YEAR(A2),MONTH(A2),DAY(A2)+C2)+TIME(HOUR(A2),MINUTE(A2)+D2,SECOND(A2))

insira a descrição da imagem aqui

Nota: ignore o erro de digitação nesta imagem. A terceira coluna deve ser rotulada como “Dias” em vez de “Horas”.

Aqui, Dia(A2)+C2 adiciona 2 dias e Minutos(A2)+D2 adiciona 20 minutos.

O resultado final na Célula E2 é 06/03/2018 às 08:20.

Observação:

  • A2 e E2 são formatados como AAAA-MM-DD HH:MM.
  • B2 é formatado como Número.
  • C2 e D2 são formatados como Geral.

Esta solução usa colunas auxiliares para auxiliar na explicação. As colunas auxiliares podem ser incorporadas em uma única fórmula, substituindo a referência da célula pela fórmula da célula auxiliar.

informação relacionada