Quero obter muitos dados da Planilha1 para a Planilha2, mas quando puxo um comando para a direita, ele só deve aumentar o "C" para "D" a cada terceira linha. Porque eu tenho 3 comandos para puxar para a direita e todos devem aumentar em um e não em 3.
A1 fica assim:
=WENN(Sheet1!C3>0;Sheet1!C$2;"")
B1 assim:
=WENN(Sheet1!C3>0;Sheet1!$A3;"")
C1 assim:
=WENN(Sheet1!C3>0;Sheet1!C3;"")
Quando puxo para a direita, eles mudam assim:
=WENN(Sheet1!F3>0;Sheet1!F$2;"")
=WENN(Sheet1!F3>0;Sheet1!$A3;"")
=WENN(Sheet1!F3>0;Sheet1!F3;"")
Mas eu quero:
=WENN(Sheet1!D3>0;Sheet1!D$2;"")
=WENN(Sheet1!D3>0;Sheet1!$A3;"")
=WENN(Sheet1!D3>0;Sheet1!D3;"")
Espero que você saiba o que quero dizer. Há alguma maneira de fazer isso?
Responder1
Você pode usar a OFFSET
função útil para controlar o quanto deseja deslocar uma célula para a direita.
Como você deseja deslocar 1 coluna (na Planilha1) a cada 3 colunas (na Planilha2), você pode usar a seguinte função:
=ROUNDUP(COLUMN()/3,0)-1
Basicamente, isso usará o número da coluna, dividirá por 3 e arredondará. Então, removemos 1, porque não queremos deslocar as 3 primeiras colunas. Se puxar para a direita, você obterá a seguinte sequência:0 0 0 1 1 1 2 2 2 3 3 3...
Agora que você sabe quanto precisa deslocar a célula C3
, pode usar a OFFSET
função para obter os dados corretos. Aqui estão as fórmulas que você deve usar em Sheet2
:
A1
=IF(OFFSET(Sheet1!$C3,0,ROUNDUP(COLUMN()/3,0)-1)>0,OFFSET(Sheet1!$C$2,0,ROUNDUP(COLUMN()/3,0)-1),"")
B1
=IF(OFFSET(Sheet1!$C3,0,ROUNDUP(COLUMN()/3,0)-1)>0,Sheet1!$A3,"")
C1
=IF(OFFSET(Sheet1!$C3,0,ROUNDUP(COLUMN()/3,0)-1)>0,OFFSET(Sheet1!$C3,0,ROUNDUP(COLUMN()/3,0)-1),"")
Resultado esperado:
Você parece estar usando o Excel em alemão. Aqui estão as fórmulas traduzidas:
=WENN(BEREICH.VERSCHIEBEN(Sheet1!$C3;0;AUFRUNDEN(SPALTE()/3;0)-1)>0;BEREICH.VERSCHIEBEN(Sheet1!$C$2;0;AUFRUNDEN(SPALTE()/3;0)-1);"")
=WENN(BEREICH.VERSCHIEBEN(Sheet1!$C3;0;AUFRUNDEN(SPALTE()/3;0)-1)>0;Sheet1!$A3;"")
=WENN(BEREICH.VERSCHIEBEN(Sheet1!$C3;0;AUFRUNDEN(SPALTE()/3;0)-1)>0;BEREICH.VERSCHIEBEN(Sheet1!$C3;0;AUFRUNDEN(SPALTE()/3;0)-1);"")