☰

Impedir que o Windows 10 hiberne apenas para o próximo fechamento da tampa

tag-icon • tag-icon windows windows-10 laptop sleep power-management
Impedir que o Windows 10 hiberne apenas para o próximo fechamento da tampa

Às vezes deixo meu computador (laptop Lenovo com Windows 10) fazer coisas que demoram um pouco (por exemplo, computação científica). Quando fizer isso, gostaria de poder fechar a tampa sem que ele durma.

O problema é que eu também gostaria de manter o comportamento padrão, onde ele dorme quando eu o fecho, na maioria das vezes.

O jeito que eu gostaria que funcionasse seria que, se eu não fizesse nada e fechasse a tampa, ele adormecesse. Se eu pressionar alguma combinação arbitrária de teclas, ela será ignorada na próxima vez que eu fechar a tampa e permanecerá acordada até abri-la novamente.

Idealmente, esse comportamento seria o mesmo conectado ou não. Eu sei que posso mudar isso em “gerenciamento de energia”, mas faço isso com frequência e seria bom ter um atalho para isso.

Alguém consegue pensar em uma maneira de fazer isso ou em algum truque para imitar esse tipo de comportamento?

Desde já, obrigado.

Responder1

Para evitar que o computador hiberne, você pode usar um programa como Cafeína ou Insônia.

Como alternativa, você pode desativar a suspensão ao fechar a tampa e reativá-la mais tarde. Se fazer isso manualmente for muito oneroso, você pode fazer isso por meio de um comando que pode ser colocado em um arquivo em lote armazenado na área de trabalho.

Veja o script de alternância, para desabilitar e restaurar a ação de fechamento da tampa para o que era antes, em esta resposta (mas as outras respostas também podem ser pertinentes).

Aqui está uma versão ligeiramente modificada do script:

@echo off
setlocal enabledelayedexpansion
for /f "tokens=2 delims=:(" %%i in ('powercfg /GETACTIVESCHEME') do set ACTIVESCHEME=%%i
for /f "tokens=2 delims=:(" %%i in ('powercfg -q %ACTIVESCHEME% SUB_BUTTONS LIDACTION ^| findstr "[0-9a-z]*-[0-9a-z]*-[0-9a-z]*-[0-9a-z]*-[0-9a-z]*"') do set FULLPATH=!FULLPATH! %%i
for /f "tokens=2 delims=:(" %%i in ('powercfg /q %FULLPATH% ^| findstr "[0-9]x[0-9]*"') do (
    set CURRENTSETTINGAC=!CURRENTSETTINGDC!
    set CURRENTSETTINGDC=%%i
)
set CURRENTSETTINGAC=%CURRENTSETTINGAC:~-1%
set CURRENTSETTINGDC=%CURRENTSETTINGDC:~-1%
powercfg -SETACVALUEINDEX %FULLPATH% 0
powercfg -SETDCVALUEINDEX %FULLPATH% 0
powercfg /s %ACTIVESCHEME%
pause Waiting to re-enable sleep on lid close ...
powercfg -SETACVALUEINDEX %FULLPATH% %CURRENTSETTINGAC%
powercfg -SETDCVALUEINDEX %FULLPATH% %CURRENTSETTINGDC%
powercfg /s %ACTIVESCHEME%

informação relacionada