☰

Código Macro/VBA para listar e imprimir nomes e códigos de todas as macros em uma pasta de trabalho

tag-icon • tag-icon microsoft-excel vba microsoft-excel-2007
Código Macro/VBA para listar e imprimir nomes e códigos de todas as macros em uma pasta de trabalho

Estou usando o Excel 2007. Para esta pergunta, o nome da minha pasta de trabalho é PrintCode.xlsm

Existe uma macro ou código VBA que imprimirá todos os nomes e códigos de macro na pasta de trabalho aberta?

Encontrei alguns exemplos na web, mas nenhum parece funcionar?

Responder1

Eu encontrei este, veja como é o que você precisa:Como recuperar os nomes de macros de uma pasta de trabalho do Excel usando Visual Basic 6.0:

Defina um procedimento de manipulador de eventos de clique para o botão. Use o código a seguir para este procedimento para exibir informações sobre as macros definidas em C:\Abc.xls:

Private Sub Command1_Click()
    ' Declare variables to access the Excel workbook.
    Dim objXLApp As Excel.Application
    Dim objXLWorkbooks As Excel.Workbooks
    Dim objXLABC As Excel.Workbook

    ' Declare variables to access the macros in the workbook.
    Dim objProject As VBIDE.VBProject
    Dim objComponent As VBIDE.VBComponent
    Dim objCode As VBIDE.CodeModule

    ' Declare other miscellaneous variables.
    Dim iLine As Integer
    Dim sProcName As String
    Dim pk As vbext_ProcKind

    ' Open Excel, and open the workbook.
    Set objXLApp = New Excel.Application
    Set objXLWorkbooks = objXLApp.Workbooks    
    Set objXLABC = objXLWorkbooks.Open("C:\ABC.XLS")

    ' Empty the list box.
    List1.Clear

    ' Get the project details in the workbook.
    Set objProject = objXLABC.VBProject

    ' Iterate through each component in the project.
    For Each objComponent In objProject.VBComponents

        ' Find the code module for the project.
        Set objCode = objComponent.CodeModule

        ' Scan through the code module, looking for procedures.
        iLine = 1
        Do While iLine < objCode.CountOfLines
            sProcName = objCode.ProcOfLine(iLine, pk)
            If sProcName <> "" Then
                ' Found a procedure. Display its details, and then skip 
                ' to the end of the procedure.
                List1.AddItem objComponent.Name & vbTab & sProcName
                iLine = iLine + objCode.ProcCountLines(sProcName, pk)
            Else
                ' This line has no procedure, so go to the next line.
                iLine = iLine + 1
            End If
        Loop
        Set objCode = Nothing
        Set objComponent = Nothing
    Next

    Set objProject = Nothing

    ' Clean up and exit.
    objXLABC.Close
    objXLApp.Quit
End Sub

informação relacionada