Adicionar unidades ao painel de navegação do explorador de arquivos do Windows

Question

Quero exibir as unidades C: e D: da mesma forma que 'Este PC' é mostrado no painel de navegação. Conheço o processo pelo qual preciso passar (vejaesta resposta), mas não sei qual local do registro devo editar. Alguém pode me indicar isso? Se possível, também gostaria de adicionar uma pasta específica em D: ao painel de navegação.

Eu tentei osoluçãofornecido por tenforums, no entanto, não foi possível adicionar as unidades.

Answer 1

Graças aSimon Mourieresua resposta paraFixar uma pasta no painel de navegação do Windows Explorer:

PinDiskD.bat. Execute para fixar o disco D:\em algum lugar acima This PCdoExplorador de arquivospainel de navegação. Execute com qualquer parâmetro não vazio para remover o disco D:\do painel, por exemplo PinDiskD.bat x(observe o :deleAllrótulo abaixo).

@ECHO OFF
SETLOCAL EnableExtensions
set "_icon=%%SystemRoot%%\system32\imageres.dll,27"
set "_name=d DataDisk"
set "_guid=ffffffff-ffff-ffff-0000-00000000000d"
set "_target=d:\\"

set "_regK=HKCU\Software\Classes\CLSID"
set "_regE=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer"
if NOT "%~1"=="" goto :deleAll
reg add %_regK%\{%_guid%} /ve /t REG_SZ /d "%_name%" /f
reg add %_regK%\{%_guid%}\DefaultIcon /ve /t REG_EXPAND_SZ /d %_icon% /f
reg add %_regK%\{%_guid%} /v System.IsPinnedToNameSpaceTree /t REG_DWORD /d 0x1 /f
reg add %_regK%\{%_guid%} /v SortOrderIndex /t REG_DWORD /d 0x42 /f
reg add %_regK%\{%_guid%}\InProcServer32 /ve /t REG_EXPAND_SZ /d %%systemroot%%\system32\shell32.dll /f
reg add %_regK%\{%_guid%}\Instance /v CLSID /t REG_SZ /d {0E5AAE11-A475-4c5b-AB00-C66DE400274E} /f
reg add %_regK%\{%_guid%}\Instance\InitPropertyBag /v Attributes /t REG_DWORD /d 0x11 /f
reg add %_regK%\{%_guid%}\Instance\InitPropertyBag /v TargetFolderPath /t REG_EXPAND_SZ /d "%_target%" /f
reg add %_regK%\{%_guid%}\ShellFolder /v FolderValueFlags /t REG_DWORD /d 0x28 /f
reg add %_regK%\{%_guid%}\ShellFolder /v Attributes /t REG_DWORD /d 0xF080004D /f
reg add %_regE%\Desktop\NameSpace\{%_guid%} /ve /t REG_SZ /d "%_name%" /f
reg add %_regE%\HideDesktopIcons\NewStartPanel /v {%_guid%} /t REG_DWORD /d 0x1 /f

:endlocal
ENDLOCAL
goto :eof

:deleAll
reg delete %_regK%\{%_guid%}                                   /f
reg delete %_regE%\Desktop\NameSpace\{%_guid%}                 /f
reg delete %_regE%\HideDesktopIcons\NewStartPanel /v {%_guid%} /f
goto :endlocal

PinDiskC.bat. Fixa o disco C:\no painel. O mesmo quePinDiskD.batexceto quatro setcomandos principais:

set "_icon=%%SystemRoot%%\system32\imageres.dll,31"
set "_name=c SystemDisk"
set "_guid=ffffffff-ffff-ffff-0000-00000000000c"
set "_target=c:\\"
…

D:\bat\PinCodePages.bat. Fixa uma pasta local específica no painel. O mesmo quePinDiskD.batexceto quatro setcomandos principais (verifique a validade das variáveis _icon​​, _namee ):_guid_target

set "_icon=%%SystemRoot%%\system32\shell32.dll,176" # any valid icon
set "_name=My Folder"                               # any valid name
set "_guid=ffffffff-ffff-ffff-0000-00000000c0de"    # a valid GUID (no braces)
set "_target=d:\Utils\CodePages\\"                  # any valid local path
…

Exemplo de como fica no Windows 10 depois de executar todos os scripts acima: