☰

Arquivo em lote do Windows para classificar subpastas

tag-icon • tag-icon windows batch cmd.exe
Arquivo em lote do Windows para classificar subpastas

Eu tenho uma pasta, C:\Users\User1\Desktop\Photos2019, com mais de 100 subpastas. Em cada uma dessas subpastas há fotos, todas com nomes variados, exceto que três fotos em cada uma são iguais. Eu gostaria de poder criar 2 subpastas em cada uma das pastas do diretório, uma chamada 'Base' e outra chamada 'Outro', e ter os 3 arquivos iguais movidos para a pasta 'Base', e todo o resto foi movido para a pasta 'Outros', algo como abaixo.

C:\Users\User1\Desktop\Photos2019
-Folder1/Base/Landscape.png
-Folder1/Base/Portrait.png
-Folder1/Base/Wide.png
-Folder1/Other/*.png

-Folder2/Base/Landscape.png
-Folder2/Base/Portrait.png
-Folder2/Base/Wide.png
-Folder2/Other/*.png

EDIT: Até agora consegui criar um script em lote que posso executar em cada pasta e ele fará o trabalho. É quando tento adicionar /r para fazer o loop, que ele continua funcionando, mas não faz o trabalho.

Eu tenho;

for %%a in (.) do md "Base"
for %%a in (.) do md "Other"
for %%a in (.) do move "Portrait.png" "Base"
for %%a in (.) do move "Landscape.png" "Base"
for %%a in (.) do move "Wide.png" "Base"
for %%a in (.) do move "*.png" "Other"

É isso que eu quero que estou tentando executar em cada subpasta.

Qual seria a melhor forma de fazer isso? Obrigado.

Responder1

Bem, atesto que a ajuda do forcomando precisa de várias iterações de leitura para ser totalmente compreendida.

Com uma árvore inicial no meu teste RamDrive A:\

> tree /f a:\
A:\
└───Test
    ├───Folder1
    │       Landscape.png
    │       other.png
    │       Portrait.png
    │       Wide.png
    │
    └───Folder2
            Landscape.png
            other.png
            Portrait.png
            Wide.png

Este lote:

:: Q:\Test\2019\08\22\SU_1473860.cmd
@Echo off
set "StartDir=C:\Users\User1\Desktop\Photos2019"
Rem set "StartDir=A:\Test"

set "Base=Landscape.png Portrait.png Wide.png"

CD /D "%StartDir%"

for /d %%D in (*) Do (
    MD "%%~fD\Base"
    MD "%%~fD\Other"
    for %%B in (%Base%) Do Move "%%~fD\%%B" "%%~fD\Base\" >Nul 2>&1
    Move "%%~fD\*.png" "%%~fD\Other" >Nul 2>&1
)

produz este resultado:

> tree /F a:\
A:\
└───Test
    ├───Folder1
    │   ├───Base
    │   │       Landscape.png
    │   │       Portrait.png
    │   │       Wide.png
    │   │
    │   └───Other
    │           other.png
    │
    └───Folder2
        ├───Base
        │       Landscape.png
        │       Portrait.png
        │       Wide.png
        │
        └───Other
                other.png

informação relacionada