☰

Reorganizando os dados da coluna com base em ordem alfabética

tag-icon • tag-icon linux awk
Reorganizando os dados da coluna com base em ordem alfabética

Quero alterar a ordem dos dados da coluna com base na ordem alfabética

Entrada

c,a,b
e,k,d

Saída

a,b,c
d,e,k

atualmente, estou usando o código abaixo

awk -F"," -v OFS="," '{ 
if($1<=$2 && $2<=$3) 
{print $1,$2,$3} 
else if($1<=$2 && $3<=$2) 
{print $1,$3,$2} 
else if($2<=$1 && $1<=$3) 
{print $2,$1,$3} 
else if($2<=$1 && $3<=$1) 
{print $2,$3,$1} 
else if($3<=$2 && $2<=$1) 
{print $3,$2,$1} 
else 
{print $3,$1,$2}}' test.txt

Você poderia me ajudar com uma solução mais simples para lidar com arquivos com 4 ou mais colunas

Responder1

Se você estiver bem com perl:

$ perl -F, -lane 'print join ",", sort @F' ip.txt
a,b,c
d,e,k

-F,especifica a linha de entrada a ser dividida ,como delimitador e o resultado está disponível via @Farray

sort @Firá classificar em ordem alfabética e a matriz resultante será combinada joinusando ,como separador


ComGNU awk

$ awk 'BEGIN{PROCINFO["sorted_in"] = "@val_str_asc"}
       {s = ""; c=0; split($0,a,",");
        for(k in a) s = c++ ? s "," a[k] : a[k];
        print s}' ip.txt
a,b,c
d,e,k

Vermanual do gawk: Usando ordens de varredura de array predefinidaspara obter detalhes sobre a ordenação de arrays usada acima

Responder2

Com GNU awk para sorted_in:

$ cat tst.awk
BEGIN {
    FS=OFS=","
}
{
    sub(/\r$/,"")
    print sort($0)
}

function sort(inStr,    arr,idx,sep,outStr) {
    PROCINFO["sorted_in"] = "@val_str_asc"
    split(inStr,arr)
    for (idx in arr) {
        outStr = outStr sep arr[idx]
        sep = OFS
    }
    return outStr
}

$ awk -f tst.awk file
a,b,c
d,e,k

ou com qualquer awk, mas será executado muito mais lentamente, pois gera um shell para chamar o UNIX sortpara cada linha de entrada:

$ cat tst.awk
BEGIN {
    FS=OFS=","
}
{
    sub(/\r$/,"")
    print sort($0)
}

function sort(inStr,    cmd,line,sep,outStr) {
    gsub(/,/,"\n",inStr)
    cmd = "printf \047%s\n\047 \047" inStr "\047 | sort"
    while ( (cmd | getline line) > 0 ) {
        outStr = outStr sep line
        sep = OFS
    }
    close(cmd)
    return outStr
}

$ awk -f tst.awk file
a,b,c
d,e,k

Isso sub(/\r$/,"")ocorre porque você tem finais de linha do DOS na entrada de amostra postada, mas não na saída esperada postada.

Responder3

perl -nlE 'say join ",", sort split ","'   file.txt

Explicação:

            for each line like "r,d,a":
 "r,d,a"
    ↓          split ","  it
("r","d","a")
    ↓          sort       it
("a","d","r")
    ↓          join ","   it
 "a,d,r"
               say it

informação relacionada