☰

como posso colocar esses dados em colunas separadas

tag-icon • tag-icon bash text-processing
como posso colocar esses dados em colunas separadas 
Frequencies -- 1403.6738 1403.6738 1403.6738
IR Inten -- 25.0809 25.0809 25.0809

Eu quero obter duas colunas

Frequencies     IR Inten
1403.6738       25.0809

e assim por diante

Responder1

Usando Raku (a linguagem de programação anteriormente conhecida como Perl6)

Raku tem um Zoperador bacana para problemas como este, para 'compactar' itens, um de cada lista:

~$ raku -e 'my @array1 = lines(); put ( [Z] @array1[0].words, @array1[1].words).join("\n");'  Freq_IR.txt
Frequencies IR_Inten
-- --
1403.6738 25.0809
1403.6738 25.0809
1403.6738 25.0809

Nota: tive que corrigir a linha do cabeçalho acima para que a segunda coluna fosse intitulada " IR_Inten". Você pode editar manualmente ou executar o código abaixo, antes de reorganizar os dados com o código acima:

~$ raku -pe 's/IR \s Inten/IR_Inten/;'  Freq_IR.txt > Freq_IR2.txt

HTH.

https://raku.org
https://docs.raku.org/linguagem/operators#Zip_metaoperator
https://docs.raku.org/language/operators#index-entry-[+]_(reduction_metaoperators)

Responder2

Usando qualquer awk em qualquer shell em cada caixa Unix:

$ awk -F' -- ' -v OFS='\t' '
    { hdr[NR]=$1; n=split($2,v," "); for (i in v) vals[NR,i]=v[i] }
    END { print hdr[1], hdr[2]; for (i=1; i<=n; i++) print vals[1,i], vals[2,i] }
' file
Frequencies     IR Inten
1403.6738       25.0809
1403.6738       25.0809
1403.6738       25.0809

e para trabalhar com qualquer número de linhas e colunas de saída:

awk -F' -- ' -v OFS='\t' '
    { hdr[NR]=$1; n=split($2,v," "); for (i in v) vals[NR,i]=v[i] }
    END {
        for (c=1; c<=NR; c++) {
            printf "%s%s", hdr[c], (c<NR ? OFS : ORS)
        }
        for (r=1; r<=n; r++) {
            for (c=1; c<=NR; c++) {
                printf "%s%s", vals[c,r], (c<NR ? OFS : ORS)
            }
        }
    }
' file

Responder3

Usando awk podemos fazer a transformação dos dados.

awk -F ' -- ' '
{
  # populate the array
  a[++N] = $1; split($2, t, " ")
  for (k in t) { a[++N] = t[k] }
}
END {ORS = ""
  for (c=i=1; i<=N/NR; i++) {
    for (j=i; j<=N; j+=N/NR) {
      print a[j] (c++%NR ? "\t" : "\n")
    }
  }
}
' file
Frequencies IR Inten
1403.6738   25.0809
1403.6738   25.0809
1403.6738   25.0809

A ideia básica é primeiro preencher o array e registrar o comprimento do array no final. Em seguida, divida a matriz em partes N/NR e escolha os elementos correspondentes de cada parte. Em outras linguagens como Python esta operação é chamada zip.

informação relacionada