estilos de linha não aplicados no gnuplot (epslatex)

Question

Olá, gostaria de desenhar 2 curvas em um mesmo gráfico usando gnuplot (terminal epslatex). Estou usando um script gnuplot, que funciona perfeitamente, exceto que não aplica cores de linha definidas usando command set style line.

Aqui está o roteiro:

set terminal epslatex color colortext size 9cm,5cm
set size 1,1
set output "lorenzov_faktor.tex"

set xrange [0:10]
set yrange [0:10]

set xtics ("$0c$" 0, "$c$" 10)
set ytics ("$0$" 0, "$1$" 1, "$\\infty$" 10)

set style line 1 lc rgb "#FF0055"
set style line 2 lc rgb "#2C397D"

unset grid

set ylabel "$\\gamma$"
set xlabel "$u$"

set key left top

f(x) = 1/sqrt(1 - (x/10)**2) 
g(x) = 1

set xrange [0:11]
set yrange [0:9]

plot f(x) ls 2 lw 3 lt 1 title "$\\gamma$", g(x) ls 1 lw 1 lt 2 notitle

Produz um gráfico onde as cores não correspondem às minhas definições de estilos de linha:

Answer 1

Você precisa excluir lt 1e lt 2do seu script, porque eles restauram os tipos de linha padrão no lugar dos estilos de linha definidos pelo usuário. Alternativamente, você pode alterar o tipo de linha (sólida, tracejada, etc.) sem afetar a cor usando ltao fazer isso set style line.

set style line 1 lc rgb "#FF0055" lt 1
set style line 2 lc rgb "#2C397D" lt 3

...

plot f(x) ls 2 lw 3 title "$\\gamma$", g(x) ls 1 lw 1 notitle