☰

Aplicar política de assinatura no Exchange 2003 usando campos do Active Directory

tag-icon • tag-icon active-directory exchange outlook
Aplicar política de assinatura no Exchange 2003 usando campos do Active Directory

Nossa organização decidiu que precisa ter um bloco de assinatura padrão para todos os usuários com base em seu nome, cargo, detalhes de contato e localização do escritório, todos armazenados no Active Directory.

Alguém encontrou uma solução interessante para gerar automaticamente assinaturas do Outlook/Exchange 2003 com base nos campos do Active Directory?

Responder1

Sou cliente de longa data e fãUtilitários de correio Exclaimer.

Ele fica no servidor Exchange e possui muitas regras personalizáveis ​​que determinam se deve ser aplicado estacionário ou não. Adicionei ao topo de todos os e-mails enviados externamente nosso logotipo corporativo e o nome das pessoas, cargo e vários números de telefone na parte inferior - todos retirados do Active Directory.

Só usei o suporte uma vez, mas eles foram muito amigáveis, experientes e resolveram meu problema muito rapidamente.

Responder2

Tive muita sorte com um roteiro que escrevi. Ele grava vários campos do AD em um documento invisível do Word e, em seguida, copia-o para o Outlook 2007 como padrão e assinatura de resposta.

Deixei de executá-lo automaticamente a cada login. Muito raramente eu teria problemas no primeiro login de um usuário em uma máquina, onde o Outlook ainda não pudesse abrir sem passar pelo assistente. A partir de agora, é um GPO que apenas envia um atalho para a área de trabalho dos usuários chamado "Redefinir assinatura de email". Isso também permite que os usuários tenham assinaturas não padrão sem que elas sejam substituídas todas as vezes.

On Error Resume Next

Set objSysInfo = CreateObject("ADSystemInfo")

strUser = objSysInfo.UserName
Set objUser = GetObject("LDAP://" & strUser)

strName = objUser.FullName
strTitle = objUser.Title
strDepartment = objUser.Department
strCompany = objUser.Company
strPhone = objUser.telephoneNumber
strFax = objUser.faxNumber

strStreet = objUser.StreetAddress
strCity = objUser.L
strState = objUser.St
strPOBox = objUser.postalCode

strFirstName = objUser.givenName
strInitials = objUser.initials
strLastName = objUser.sn
If strInitials = "" Then
    strFullName = strFirstName & " " & strLastName
Else
    strFullName = strFirstName & " " & strInitials & ". " & strLastName
End If

Set objWord = CreateObject("Word.Application")

Set objDoc = objWord.Documents.Add()
Set objSelection = objWord.Selection
objSelection.Style = "No Spacing" 
objSelection.Font.Name = "Calibri"
objSelection.Font.Size = "11"

Set objEmailOptions = objWord.EmailOptions
Set objSignatureObject = objEmailOptions.EmailSignature

Set objSignatureEntries = objSignatureObject.EmailSignatureEntries

objSelection.TypeParagraph()
objSelection.TypeText "Sincerely,"
objSelection.TypeParagraph()
objSelection.TypeParagraph()
objSelection.TypeText "ORGANIZATION NAME"
objSelection.TypeParagraph()
objSelection.TypeParagraph()
objSelection.TypeText strFullName & ", " & strTitle
'objSelection.TypeText strName & ", " & strTitle
objSelection.TypeParagraph()
objSelection.TypeParagraph()
objSelection.TypeText strStreet
objSelection.TypeParagraph()
objSelection.TypeText strCity & ", " & strState & " " & strPOBox
objSelection.TypeParagraph()
objSelection.TypeText "Desk: " & strPhone
objSelection.TypeParagraph()
objSelection.TypeText "Fax:    " & strFax
objSelection.TypeParagraph()

'Hyperlink below
objDoc.Hyperlinks.Add objSelection.Range, "www.yoursitename.com", "", "", "www.yoursitename.com", ""

objSelection.TypeParagraph()
objSelection.TypeParagraph()

'Picture below
Set objShape = objSelection.InlineShapes.AddPicture("\\fileserver\path\to\image.BMP")

Set objSelection = objDoc.Range()

objSignatureEntries.Add "AD Signature", objSelection
objSignatureObject.NewMessageSignature = "AD Signature"
objSignatureObject.ReplyMessageSignature = "AD Signature"

objDoc.Saved = True
objWord.Quit

Se você tiver alguma dúvida é só me avisar!

informação relacionada