☰

изменить определенные столбцы на основе другого столбца с помощью awk и gsub

tag-icon • tag-icon bash xubuntu windows-subsystem-for-linux linux-headers
изменить определенные столбцы на основе другого столбца с помощью awk и gsub

У меня есть файл (file1) с миллионами строк и столбцов. Пример данных:

"col1","col2","col3","col4","col5","col6"
"AAA",0,5,10,"BGB",50
"BBB",4,7,10,"BFD",76
"AAA",15,0,0,"BGB",20
"AAA",10,13,10,"DDD",23

Я хочу найти все строки, которые содержат AAA в col1, а затем получить все строки, которые содержат BGB в col5. И, наконец, уменьшить 50% каждого значения в col2, col3, col4 и col6 (игнорировать, если значения ячеек равны 0 или пусты). И вывести все строки файла. Итак, мой вывод будет выглядеть следующим образом:

"col1","col2","col3","col4","col5","col6"
"AAA",0,2.5,5,"BGB",25
"BBB",4,7,10,"BFD",76
"AAA",7.5,0,0,"BGB",10
"AAA",10,13,10,"DDD",23

Я пробовал следующее, но не смог заставить это работать (также не смог понять, как использовать несколько столбцов в gsub)

grep AAA file1 | awk -F "," '$5~/BGB/ {gsub($6,\substr($6,1,length($6)-1)*0.50\, $6}1'

решение1

awk может сопоставлять шаблоны, как это делает grep, поэтому вам почти никогда не понадобится grep и awk в конвейере.

Ты мог бы сделать

 awk  '
    BEGIN {FS = OFS = ","}
    $1 ~ /AAA/ && $5 ~ /BGB/ {
        if ($2) $2 = $2 / 2
        if ($3) $3 = $3 / 2
        if ($4) $4 = $4 / 2
        if ($6) $6 = $6 / 2
    }
    1
' file

Или, если вы хотите сделать столбцы более динамичными,

awk -v "columns=2,3,4,6" '
    BEGIN {
        FS = OFS = ","
        n = split(columns, a, /,/)
        for (i=1; i<=n; i++) cols[a[i]]=1
    }
    $1 ~ /AAA/ && $5 ~ /BGB/ {
        for (c in cols) if ($c) $c = $c / 2
    }
    1
' file

Связанный контент