☰

Есть ли программа для анализа статистики NTP-сервера?

tag-icon • tag-icon 12.04 ntp
Есть ли программа для анализа статистики NTP-сервера?

Я использую Ubuntu 12.04 и у меня работает сервер NTP, судя по всему, все в порядке. Я запускаю сервер Meinberg NTP на двух моих ящиках Windows 7 и использую связанный с ним монитор сервера, чтобы отслеживать, что он делает.

Есть ли аналогичный монитор для Linux, желательно с графическим интерфейсом, который может показать мне, как ведут себя мои часы и т. д.?

решение1

Не точный ответ на ваш вопрос, но я вижу, что вы упомянули, что теперь используете скрипт gnuplot, который анализирует /var/log/ntp/loopstats. Я делаю то же самое, и ниже приведен тот, который я использую сам.

Если кто-то делает что-то лучше, мне тоже было бы любопытно.

#! /usr/bin/gnuplot
# Remember to check you have these lines in /etc/ntp.conf and that ntpd is actually running:
#    statsdir /var/log/ntpstats/
#    statistics loopstats peerstats clockstats
#    filegen loopstats file loopstats type day enable
#    filegen peerstats file peerstats type day enable
#    filegen clockstats file clockstats type day enable

# Resolution: fullscreen
set term x11 size `xrandr | awk '/\*/{sub(/x/,",");print $1; exit}'`
set grid
set bars 0.4
set y2tics
set y2range [0:]
set ytics nomirror
set xdata time
set timefmt "%s"
set format x "%T"
set title "NTP statistics"
set ylabel "Clock offset / Roundtrip delay (ms)"
set y2label "Frequency offset (seconds per day)"
set xlabel "Time of day"
local_time = `date +%s --utc -d "12:00:00 $(date +%z)"`
utc_time   = `date +%s --utc -d "12:00:00"`
localdifferencefromUTC = utc_time - local_time
timeoffsettoday = `date +%s --utc -d "today 0:00"` + localdifferencefromUTC
plot \
  "/var/log/ntpstats/loopstats" u ($2+timeoffsettoday):($3*1000):($5*1000/2) t "Clock offset" w errorlines lt 1 lw 2 pt 187, \
  "/var/log/ntpstats/peerstats" u ($2+timeoffsettoday):($6*1000):($8*1000/2) t "Roundtrip delay" w errorbars lt 26 pt 26,\
  "/var/log/ntpstats/loopstats" u ($2+timeoffsettoday):($4*0.0864):($6*0.0864/2) axes x1y2 t "Frequency offset" w errorline lt 7 pt 65,\
  0 w l lt -1
pause mouse close

решение2

ntp.org предлагает множествоссылкик инструментам мониторинга на своем веб-сайте

Связанный контент