☰

sed подсчет строк между шаблонами - несколько файлов

tag-icon • tag-icon bash text-processing sed pipe wc
sed подсчет строк между шаблонами - несколько файлов

У меня есть несколько .txtфайлов в одном каталоге. Каждый файл имеет раздел:

DONE
item 1
item 2
item 3
DONE

Я хотел бы подсчитать количество строк между двумя DONEмаркерами для каждого файла отдельно.

я использовалэтот вопросчтобы создать это:

sed -n "/DONE/,/DONE/ p" *.txt | wc -l > ~/word_count.txt

Но это объединяет счетчики для каждого файла в одно число. Вместо этого я хотел бы получить такой вывод:

file1.txt 3
file2.txt 5
file3.txt 6

решение1

Лучше использовать awkдлясчитать.

awk '
  FNR == 1 {inside = 0}
  $0 == "DONE" {
    if (inside) print FILENAME, n
    n = 0
    inside = ! inside
    next
  }
  inside {n++}' ./*.txt

Это напечатает запись для каждого DONE...DONEраздела в каждом файле, что означает, что ничего не будет напечатано, если такого раздела нет. Чтобы напечатать 0для них, вам понадобится реализация GNU awkс ее BEGINFILEспециальными ENDFILEоператорами:

awk '
  BEGINFILE {DONE_count = 0}
  $0 == "DONE" {
    if (++DONE_count % 2 == 0) print FILENAME, n
    n = 0
    next
  }
  DONE_count % 2 {n++}
  ENDFILE {if (!DONE_count) print FILENAME, 0}' ./*.txt

Или запустите по одному awkдля каждого файла:

for file in ./*.txt; do
  awk '
    $0 == "DONE" {
      if (++DONE_count % 2 == 0) print FILENAME, n
      n = 0
      next
    }
    DONE_count % 2 {n++}
    END {if (!DONE_count) print FILENAME, 0}' "$file"
done

решение2

perl -lne '
   eof and !$a && print "$ARGV: ", 0+$a;          # no DONEs => ans=0
   next unless /DONE/ && !$a ... /DONE/;          # skip non-DONE ranges
   /DONE/ and !$a++ && next;                      # begin DONE range
   !/DONE/ and !eof and $a++,next;                # middle of DONE range
   !/DONE/ and eof and $a=2;                      # lone DONE => ans=0
   print "$ARGV: ", ($a-2, $a=0, close ARGV)[0];  # end of DONE range
                                                  # at the end we do 4 things: 1) subtract 2 from sum, 2) print filename+sum, 3) reset sum, and 4) skip the current file and jump to the next file in queue.
' ./*.txt

С помощью этого sedмы можем сделать это для каждого файла отдельно:

for f in ./*.txt; do
   printf '%s: %d\n' "$f" "$(sed -e '/DONE/,/DONE/!d; //d' "$f" | wc -l)"
done

Разница будет в сценарии, когда у нас не будет закрытия DONE.

Связанный контент