☰

эквивалентный код sed для AIX

tag-icon • tag-icon sed aix
эквивалентный код sed для AIX

Может ли кто-нибудь дать мне эквивалентный код для приведенного ниже кода sed? Он отлично работает в Linux. Однако при запуске в AIX я получаю ошибку «sed: 0602-403 /Имя политики:/! d не является распознанной функцией».

sed -n '
/Policy Name:/! d
    s/.*:\s\+//
    h
    :1
    n
    /Active:\s*no/d
    /HW\//!b1
    :2
    s/.*\s\(\S*\)\s*/\1/
    G
    s/\n/\t/p
    n
    /^\s*$\|Include:/! b2
    '

Входной файл

Policy Name:       Today

  Policy Type:       Standard
  Active:              yes
  Effective date:      01/24/2014 11:17:05
  Client Encrypt:      no
  LC/CY/Custmr:  EU         NY  Cindy
                 BU         CA  Victor
                 GU         MI  Bob
  Include:
Policy Name:       Tomorrow

  Policy Type:       Oracle
  Active:              yes
  Effective date:      01/26/2014 11:17:05
  Client Encrypt:      no
  LC/CY/Custmr:  MU         LA  Martha
                 EU         CA  Sam
  Include:
Policy Name:       Yesterday

  Policy Type:       Oracle
  Active:              no
  Effective date:      01/21/2014 11:17:05
  Client Encrypt:      no
  LC/CY/Custmr:  NV         IL  Joe

  Include:

Желаемый результат

Cindy    Today     Standard
Victor   Today     Standard
Bob      Today     Standard
Martha   Tomorrow  Oracle
Sam      Tomorrow  Oracle

решение1

# define constants
SPC=`echo x | tr x '\040'`
TAB=`echo x | tr x '\011'`
 NL=

# custom regex for...
s="[$SPC$TAB]";   # horizontal whitespace
S="[^$SPC$TAB]";  # non-whitespace

# POSIX compliant sed code...
sed -ne "
   /Policy Name:/!d

   s/.*:$s\{1,\}//
   h

   :1
      n
      /Active:$s*no/d
   /HW\//!b1

   :2
      s/.*$s\($S*\)$s*/\1/
      G
      s/\n/$TAB/p
      n
      /^$s*\$/d
      /Include:/d
   b2
"  yourfile

Комментарии

  • AIX sedне понимает \s \Sкак пробел или не пробел.
  • POSIX sedне понимает пробел перед sedкомандой, в вашем случае /.../! d.
  • Также обратите внимание, что это \+не POSIX. Правильное выражение для этого: \{1,\}или $s$s*где $s — атомы регулярных выражений.
  • \tтоже не POSIX. Здесь переменная оболочки $TABоказывается полезной.
  • Для \|операции ORв sedесть non-POSIX. Нам нужно разбить ее на части и перестроить логику.

Предостережение

  1. Может быть, вы shellпытаетесь сделать расширение истории вокруг !dперсонажа. В этом случае используйте одинарные кавычки вокруг этого региона. Для остальных двойные кавычки необходимы для того, чтобы $s, $S, $TABпеременные могли быть расширены.
  2. Регулярное $Sвыражение БУДЕТ соответствовать a, \nкак показано. Но этот сценарий никогда не возникнет в вашем коде, поскольку вы меняете NL -> TAB.

решение2

Это переработанный код для включения имен политик, а также для соответствия POSIX. Обратите внимание, что все ссылки на \s-> [[:space:]], \S-> [^[:space:]], \+->\{1,\}

PS: Не уверен, что /HW\//!b1делает эта строка в исходном коде, она там как appendix, что может оказаться болезненным, если не быть осторожным.

TAB=`printf '\t'`; # literal TAB char will be used below
sed -ne '
   /^Policy Name:/!d

   s/.*:[[:space:]]\{1,\}//;h

   :1
      n
      /Active:[[:space:]]\{1,\}no/d
      /^[[:space:]]*Policy Type:/{
         s/.*:[[:space:]]\{1,\}//;H
      }
   \|^[[:space:]]*LC/CY/Custmr:|!b1

   :2
      s/.*[[:space:]]\([^[:space:]]*\)[[:space:]]*/\1/
      G;s/\n/'"${TAB}"'/pg;n
      /^[[:space:]]*$/d
      /Include:/d
   b2
' yourpolicyfile

Полученные результаты

Cindy   Today   Standard
Victor  Today   Standard
Bob     Today   Standard
Martha  Tomorrow        Oracle
Sam     Tomorrow        Oracle

Связанный контент