Windows XP и более поздние версии

Question

В пакетном файле мне нужно извлечь месяц, день, год из команды date. Поэтому я использовал следующее, которое по сути разбирает команду Date, чтобы извлечь ее подстроки в переменную:

set Day=%Date:~3,2%
set Mth=%Date:~0,2%
set Yr=%Date:~6,4%

Все это замечательно, но если я разверну этот пакетный файл на машине с другими региональными/страновыми настройками, произойдет сбой, поскольку месяц, день и год находятся в разных местах.

Как извлечь месяц, день и год независимо от формата даты?

Answer 1

Источник: http://ss64.com/nt/syntax-getdate.html

Метод 2 (отдельная команда)

_{ПолучитьДата.cmd}

@Echo off
:: Check WMIC is available
WMIC.EXE Alias /? >NUL 2>&1 || GOTO s_error

:: Use WMIC to retrieve date and time
FOR /F "skip=1 tokens=1-6" %%G IN ('WMIC Path Win32_LocalTime Get Day^,Hour^,Minute^,Month^,Second^,Year /Format:table') DO (
   IF "%%~L"=="" goto s_done
      Set _yyyy=%%L
      Set _mm=00%%J
      Set _dd=00%%G
      Set _hour=00%%H
      SET _minute=00%%I
)
:s_done

:: Pad digits with leading zeros
      Set _mm=%_mm:~-2%
      Set _dd=%_dd:~-2%
      Set _hour=%_hour:~-2%
      Set _minute=%_minute:~-2%

:: Display the date/time in ISO 8601 format:
Set _isodate=%_yyyy%-%_mm%-%_dd% %_hour%:%_minute%
Echo %_isodate%
pause

---

Метод 1 (cmd+vb)

_{ПолучитьДата.cmd}

@Echo off
For /f %%G in ('cscript /nologo getdate.vbs') do set _dtm=%%G
Set _yyyy=%_dtm:~0,4%
Set _mm=%_dtm:~4,2%
Set _dd=%_dtm:~6,2%
Set _hh=%_dtm:~8,2%
Set _nn=%_dtm:~10,2%
Echo %_yyyy%-%_mm%-%_dd%T%_hh%:%_nn%

_getdate.vbs

Dim dt
dt=now
'output format: yyyymmddHHnn
wscript.echo ((year(dt)*100 + month(dt))*100 + day(dt))*10000 + hour(dt)*100 + minute(dt)

Answer 2

Windows XP и более поздние версии

_{получитьДата.cmd}

@echo off
for /f "tokens=2 delims==" %%G in ('wmic os get localdatetime /value') do set datetime=%%G

set year=%datetime:~0,4%
set month=%datetime:~4,2%
set day=%datetime:~6,2%

echo %year%/%month%/%day%

_Выход

Answer 3

Я знаю, что это не совсем то, что вы просили, но я использую порт Windows приложения Linux dateиз команды внутри пакетного файла, а затем присваиваю результат переменной.

Мне еще предстоит найти способ надежного получения даты, используя только пакетные команды.

Answer 4

Хотя вы правы в том, что VS 2008 выводит пакетный файл, вы можете запустить практически любую программу, какую захотите, включая скрипты Powershell и другие программы.

Редактировать:

Вот несколько похожих вопросов:

https://stackoverflow.com/questions/1051845/visual-studio-2008-professional-build-process https://stackoverflow.com/questions/3049369/embed-application-compilation-time-stamp

Первоначально я собирался перенести это в SO...