☰

Как сохранить только самые последние сообщения с заданной темой в Outlook 2007?

tag-icon • tag-icon microsoft-outlook microsoft-outlook-2007
Как сохранить только самые последние сообщения с заданной темой в Outlook 2007?

У нас есть автоматизированная система, которая отправляет обновления по электронной почте. Это нормально, и для меня это полезная информация. Я бы предпочел видеть только самые последние обновления, а все остальное удалить. То есть, учитывая следующий список

введите описание изображения здесь

Я бы хотел, чтобы в моей папке осталась только выбранная версия обновления 34022. Я покопался в Правилах, но ничего не подходит.

Есть ли способ (автоматически) удалить те, которые мне не нужны?

решение1

С некоторым VBA. Всегда хорошая идея тщательно протестировать, когда речь идет об удалении.

Private Sub Application_NewMail()
' In ThisOutlookSession module

' see Create Outlook Rules Programmatically
' http://msdn.microsoft.com/en-us/library/aa163981(v=office.10).aspx

Dim olApp As Outlook.Application
Dim olNs As Outlook.NameSpace
Dim olFld As Outlook.MAPIFolder
Dim objMail As Object

Set olApp = Outlook.Application
Set olNs = olApp.GetNamespace("MAPI")
Set olFld = olNs.GetDefaultFolder(olFolderInbox)

olFld.items.sort "Received", False
'Set objMail = olFld.items.GetFirst ' In Outlook 2003
Set objMail = olFld.items.GetLast ' In Outlook 2010

If TypeOf objMail Is MailItem Then

    If objMail.SenderEmailAddress = "Found in DetermineSenderEmailAddress" And _
        InStr(1, objMail.Subject, "Ticket:") Then

            DeleteOldStatus objMail

    End If

End If

Set objMail = Nothing
Set olFld = Nothing
Set olNs = Nothing
Set olApp = Nothing

End Sub

Sub DeleteOldStatus(objMail As MailItem)

Dim olFld As folder
Dim olNs As NameSpace
Dim olderMail As MailItem

Dim iDel As Long

Set olNs = Application.GetNamespace("MAPI")
Set olFld = olNs.GetDefaultFolder(olFolderInbox)

For iDel = olFld.items.Count To 1 Step -1

    Set olderMail = olFld.items(iDel)

    If olderMail.Subject = objMail.Subject Then

        If olderMail.ReceivedTime < objMail.ReceivedTime Then

            Debug.Print olderMail.Subject & " received  " & olderMail.ReceivedTime & " should be deleted."
            'olderMail.Delete ' Remove leading apostrophe to uncomment when ready

        End If

    End If

Next

Debug.Print "Done - " & objMail.Subject

End Sub


Sub DetermineSenderEmailAddress()

' open up an email then run

Dim currItem As MailItem
Set currItem = ActiveInspector.currentItem

' Copy the text from the immediate pane.
Debug.Print currItem.SenderEmailAddress

End Sub

Справка по редактору и кнопкам -http://www.slipstick.com/developer/how-to-use-outlooks-vba-editor/

Уровень безопасности макросов следует установить на средний.

Кнопка помощи -http://www.howto-outlook.com/howto/macrobutton.htm

Редактировать: Исправлена ​​строка InStr.

Связанный контент