☰

Excel — создание текстового файла с именем ячейки, содержащей данные других ячеек

tag-icon • tag-icon microsoft-excel vba
Excel — создание текстового файла с именем ячейки, содержащей данные других ячеек

Я хочу создать .txt fileдля каждого значения в , column Aсодержащем соответствующие значения вcolumns B and C

решение1

Чем больше я смотрел на это, тем больше находил это полезным маленьким макросом. Чтобы он не обрабатывал пустые строки (и не блокировал мой Excel), я переписал код так, чтобы он создавал файл только при наличии доступных данных. Кроме того, использование printвместо writeсоздает текст без кавычек. Вот что я использовал для достижения того же самого.

Sub CreateFile()
Do While Not IsEmpty(ActiveCell.Offset(0, 1))
    MyFile = ActiveCell.Value & ".txt"
    'set and open file for output
    fnum = FreeFile()
    Open MyFile For Output As fnum
    'use Print when you want the string without quotation marks
    Print #fnum, ActiveCell.Offset(0, 1) & " " & ActiveCell.Offset(0, 2)
Close #fnum
ActiveCell.Offset(1, 0).Select
Loop
End Sub

Можете свободно использовать и изменять по своему усмотрению. Спасибо за прекрасную идею.

решение2

Этот макрос берет каждое значение в column A, создает .txt documentв имени значения и вставляет соответствующую информацию изcolumns B and C

Sub CreateTxt()
'
For Each ce In Range("A1:A" & Cells(Rows.Count, 1).End(xlDown).Row)
    Open ce & ".txt" For Output As #1
    Write #1, ce.Offset(0, 1) & " " & ce.Offset(0, 2)
    Close #1
Next ce
End Sub

Четыре года спустя я решил вернуться к своему первому вопросу SU - моим самым первым шагам в VBA. Это лучше, но перезапишет любой файл, который уже существует

Option Explicit

Sub CreateFileEachLine()

    Dim myPathTo As String
    myPathTo = "C:\Users\path\to\"
    Dim myFileSystemObject As Object
    Set myFileSystemObject = CreateObject("Scripting.FileSystemObject")
    Dim fileOut As Object
    Dim myFileName As String

    Dim lastRow As Long
    lastRow = Cells(Rows.Count, 1).End(xlUp).Row
    Dim i As Long

        For i = 1 To lastRow
            If Not IsEmpty(Cells(i, 1)) Then
                myFileName = myPathTo & Cells(i, 1) & ".txt"
                Set fileOut = myFileSystemObject.CreateTextFile(myFileName)
                fileOut.write Cells(i, 2) & "    " & Cells(i, 3)
                fileOut.Close
            End If
        Next

    Set myFileSystemObject = Nothing
    Set fileOut = Nothing
End Sub

Связанный контент