☰

Переключатели локального подключения Windows 7 для отключения после перезагрузки

tag-icon • tag-icon windows-7 home-networking
Переключатели локального подключения Windows 7 для отключения после перезагрузки

Мне нужна помощь, чтобы мой ПК (Windows 7) оставался подключенным к сети. Я узнал, как вернуться в сеть, изменив локальное подключение с выключенного на включенное. Но подключение снова переключается на выключенное после запуска или перезагрузки ПК. Кто-нибудь знает, что мне нужно сделать, чтобы сохранить настройки включенными?

решение1

Решение заключается в написании пакетного файла для включения локальной сети и его запуске при запуске системы. Это не лучший способ. Но, определенно лучше, чем проходить через переустановки.

Шаг 1 — Получите devcon

Загрузите devcon.exe отсюда: http://download.microsoft.com/download/1/1/f/11f7dd10-272d-4cd2-896f-9ce67f3e0240/devcon.exe

Поместите devcon.exe в тот же каталог, что и пакетный файл.

Шаг 2 — Получите имя адаптера

Перейдите в панель управления > центр управления сетями и общим доступом. Нажмите на изменение параметров адаптера на левой панели.

Найдите проблемное LAN-подключение и запишите имя адаптера. Это что-то вродеBroadcom NetXtreme Gigabit Ethernet

В качестве альтернативы вы можете перейти в командную строку и использоватьipconfig /all

Найдите подключение LAN и обратите внимание на "Описание" для него. Описание - это не что иное, как имя адаптера.

Шаг 3 — пакетный файл

Теперь, когда у вас есть имя адаптера, поместите его в этот пакетный файл:

@echo off
goto Start

rem Use this batch file to enable or disable a device
rem from the Command Prompt.

:Start
setlocal enabledelayedexpansion
set Adapter=<PUT YOUR ADAPTER NAME HERE>

if /i "%1"=="enable" goto go
if /i "%1"=="disable" goto go
echo Syntax: Device enable / disable
goto :eof

:go
set HWID=x
set count=0
set found=no

devcon hwids "PCI\*" > device.txt
for /F "tokens=*" %%* in (device.txt) do (
set /a count=!count! + 1
if /i "%%*"=="Name: %Adapter%" set found=yes& set count=1
if !found!==yes if !count!==3 set HWID=%%*
)
if %found%==yes (
echo HWID=!HWID!
devcon %1 "!HWID!"
) else (
echo Device "%Adapter%" not found.
)
endlocal
del device.txt

Сохраните как abc.bat и протестируйте пакетный файл.

Синтаксис использования пакета следующий:

abc.bat enable

Если это сработает, то запланируйте его запуск при загрузке компьютера.

Связанный контент